2
$\begingroup$

I want to solve a system of equations using Findroot as follows:

Clear[a]; Clear[c]; n = 2;
SysEqn1 = Table[a[i] + I Sum[(PolyLog[1, E^(I (c[j] - a[i] + 0.5))] + 
    PolyLog[1, E^(I (c[j] - a[i] + (2 \[Pi] - 1.2)))] - 
    PolyLog[1, E^(I (c[j] - a[i] - 0.3))] - 
    PolyLog[1, E^(I (c[j] - a[i] - 0.4))]), {i, n}], {j, n}];
SysEqn2 = Table[c[i] + I Sum[(PolyLog[1, E^(I (c[j] - a[i] + 0.5))] + 
    PolyLog[1, E^(I (c[j] - a[i] + (2 \[Pi] - 1.2)))] - 
    PolyLog[1, E^(I (c[j] - a[i] - 0.3))] - 
    PolyLog[1, E^(I (c[j] - a[i] - 0.4))]), {i, n}], {j, n}];
SysEqn = Join[SysEqn1, SysEqn2]; 
startingValues1 = Table[{a[i], -1 + 2 i/n}, {i, n}]; 
startingValues2 = Table[{c[i], -0.9 + 2 i/n}, {i, n}]; 
starting = Join[startingValues1, startingValues2];
FindRoot[SysEqn, starting]

The error message from the above code is as fo

FindRoot::nlnum: "The function value {a[i]+(0. +1.\ I)\ (1.\ Log[1. +Times[<<2>>]]+1.\ Log[1. +Times[<<2>>]]-1.\ Log[1. +Times[<<2>>]]-1.\ Log[1. +Times[<<2>>]]+1.\ Log[1. +Times[<<2>>]]+1.\ Log[1. +Times[<<2>>]]-1.\ Log[1. +Times[<<2>>]]-1.\ Log[1. +Times[<<2>>]]),a[i]+(0. +1.\ I)\ (<<1>>),<<1>>,c[i]+(0. +1.\ I)\ (1.\ Log[1. +Times[<<2>>]]+<<11>>)} is not a list of numbers with dimensions {4} at {a[1],a[2],c[1],c[2]} = {0.,1.,0.1,1.1}."

For n=2 case, I have four equations so I think the number of starting variables that should be determined is also four. But for some reason my code doesn't work... I would really appreciate if you can help me out with this problem!

$\endgroup$
3
  • 1
    $\begingroup$ "I have no idea how to write the summation symbol here" - re-express them with Sum[], and then copy it here. Otherwise, I guarantee no one is going to bother trying to re-type all of that just to help you. $\endgroup$ Commented May 20, 2017 at 14:27
  • $\begingroup$ See How to copy code from Mathematica so it looks good on this site $\endgroup$
    – Bob Hanlon
    Commented May 20, 2017 at 15:34
  • $\begingroup$ I put you edit with your original question. (That's how the site is supposed to work: you edit your question to fix it up.) $\endgroup$
    – Michael E2
    Commented May 20, 2017 at 20:11

1 Answer 1

0
$\begingroup$

First of all, there seems to be a bug:

PolyLog[1, E^(I (c[1] - a[2] + (2 π - 1.2)))]
(*  -1. Log[1 - 2.71828^((0. + 1. I) (5.08319 - 1. a[2.] + c[1.]))]  *)

Note the indices have been converted from Integer to Real numbers. This can be easily fixed with NHoldAll.

Second, there's an a[i] and c[i] at the beginning of Table in each system, but the Table iterator is j. Looking at the image posted in the original form of the question, it seems the j iterator for the Sum was misplaced in the edit.

ClearAll[a];
ClearAll[c];
SetAttributes[a, NHoldAll];
SetAttributes[c, NHoldAll];
n = 2;
SysEqn1 = Table[a[i] + I Sum[(PolyLog[1, E^(I (c[j] - a[i] + 0.5))] + 
        PolyLog[1, E^(I (c[j] - a[i] + (2 π - 1.2)))] - 
        PolyLog[1, E^(I (c[j] - a[i] - 0.3))] - 
        PolyLog[1, E^(I (c[j] - a[i] - 0.4))]), {j, n}], {i, n}];
SysEqn2 = Table[c[i] + I Sum[(PolyLog[1, E^(I (c[j] - a[i] + 0.5))] + 
        PolyLog[1, E^(I (c[j] - a[i] + (2 π - 1.2)))] - 
        PolyLog[1, E^(I (c[j] - a[i] - 0.3))] - 
        PolyLog[1, E^(I (c[j] - a[i] - 0.4))]), {j, n}], {i, n}];
SysEqn = Join[SysEqn1, SysEqn2];
startingValues1 = Table[{a[i], -1 + 2 i/n}, {i, n}];
startingValues2 = Table[{c[i], -0.9 + 2 i/n}, {i, n}];
starting = Join[startingValues1, startingValues2];

FindRoot[SysEqn, starting]
(*
  {a[1] -> 1.8484 + 0.907529 I, a[2] -> 3.0128 + 1.14394 I, 
   c[1] -> 1.8484 + 0.907529 I, c[2] -> 3.0128 + 1.14394 I}
*)
$\endgroup$
2
  • $\begingroup$ I don't know if making the indices of a and c into reals is a bug or not. It goes back at least to V9. It also happens with ChebyshevT, but not with BesselJ. One could check other indexed families of functions. $\endgroup$
    – Michael E2
    Commented May 20, 2017 at 20:33
  • $\begingroup$ Oh, I found that the error message still shows up without "SetAttributes" even though i and j are swapped. But with "SetAttributes" it looks like there is no problem. Thanks a lot!! $\endgroup$
    – StudyHard
    Commented May 20, 2017 at 21:20

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.