Mathematica Stack Exchange is a question and answer site for users of Wolfram Mathematica. It only takes a minute to sign up.
Sign up to join this community
I have a dialog, which, when pops up, requests input from the user. How can I set the window up that the focus is on the InputField of the new window (i.e. the caret stands in the InputField), so that when the user starts typing, it is immediately registered by the field? At the moment, I have to click inside the field first to make it the active control on screen.
DialogInput[{InputField["", String], Button["Ok", DialogReturn[]]}]
After István Zachar's points, I was investigating Input definitions to learn more. It seams that 2 years later WRI changed approach from SelectionMove based to more automatic BoxReferenceFind.
So what we only have to do is to set BoxID option for fields of interest and find those references when we want, with:
MathLink`CallFrontEnd[
FrontEnd`BoxReferenceFind[
FE`BoxReference[
_NotebookObject, {{ID_String}},
FE`BoxOffset -> {FE`BoxChild[1]},
FE`SearchStart -> "StartFromBeginning"
]
]
]
This is a way more flexible approach, e.g. you can easily put InputField somewhere else and you don't have to change SelectionMove steps to get there.
DynamicModule[{name = "", surname = "", setFocus}
, Column[{
InputField[Dynamic@name, String, BoxID -> "name"]
, InputField[Dynamic@surname, String, BoxID -> "surname"]
, Button["setFocusToFirst", setFocus[EvaluationNotebook[], "name"]]
}]
, SynchronousInitialization -> False
, Initialization :> (
setFocus[nb_, ID_] := MathLink`CallFrontEnd[
FrontEnd`BoxReferenceFind[ FE`BoxReference[
nb
, {{ID}}
, FE`BoxOffset -> {FE`BoxChild[1]}
, FE`SearchStart -> "StartFromBeginning"
]]
]
; setFocus[EvaluationNotebook[], "surname"]
)
]
CellDynamicExpression wasn't fully fixed: mathematica.stackexchange.com/q/126655/5478. I will delete this example as this is a long term problem and I don't believe it will be fixed anytime soon. Thanks for a feedback.
$\endgroup$
Since Input is a DialogInput, it seemed reasonable to peek into Input's structure to understand how the focus is set. After removing the ReadProtected attribute I've realized that there is no neat way to do it, as WRI itself has done the reposition of the focus via successive SelectionMove calls.
This example below is not the original but a modified version, as the original Input definition only includes one InputField but no other expressions (like a Button). Note that it is not documented that you can use Initialization in dialogs, moreover it is colored red by the syntax highlighter to suggest an invalid option.
DialogInput[{InputField["", String], Button["Ok", DialogReturn[]]},
Initialization :> (FrontEndExecute[{
FrontEnd`SelectionMove[#1, Before, Notebook,
AutoScroll -> False],
FrontEnd`SelectionMove[#1, Next, Cell, 2, AutoScroll -> False],
FrontEnd`SelectionMove[#1, Previous, CellContents,
AutoScroll -> False],
FrontEnd`FrontEndToken[#1, "MovePreviousPlaceHolder"]
}] &), ShowCellBracket -> True, Selectable -> True]
FrontEnd`ReferenceBoxFind which is quite handy and more general.
$\endgroup$
ReferenceBox* and BoxReference* functions? It is hard to experiment with them without any pointer on what they do.
$\endgroup$
Apr 10, 2015 at 16:23
BoxID almost everythere and it can be simple string.
$\endgroup$
What's wrong with Input[""]?
Input but as Spartacus has pointed out, it is not general enough. Nevertheless, this pointed me to the right direction, so thanks David!
$\endgroup$
Feb 7, 2012 at 23:29
Input's structure?
$\endgroup$
Attributes[Input] = {}) and then querying the definition as ??Input. This trick could give useful insight only if the symbol is ReadProtected (meaning that most of its definition is written in Mathematica instead of C or whatnot), or not even then.
$\endgroup$
Feb 8, 2012 at 0:13