3
$\begingroup$

I have a following equation, which has a singular kernel,

0.282095` Integrate[
    Derivative[1][A11][k]/Sqrt[-k + t] , {k, 0, 
     t}] + ((-1 + E^A11[t]) Derivative[1][A11][t])/(Sqrt[
      2] Sqrt[-1 + E^A11[t] - A11[t]]) == 
 0.5` (0.2` - 0.0433792711308264` Sqrt[-1 + E^A11[t] - A11[t]] + 
    A11[t] - 
    0.015336865356479351` Integrate[(2 Sqrt[
          1/(-k + t)] Derivative[1][A11][k])/Sqrt[π] , {k, 0, t}])

and the Initial condition is A11[0]==0

I used following series expansion for the nonlinear parts

Series[Sqrt[-1 + E^A11[t] - A11[t]], {A11[t], 0, 3}]
Series[(-1 + E^A11[t]), {A11[t], 0, 3}]

The above expressions are replaced in the equation, Then I used Laplace transform to solve the equation, where the answer is

A11[s_] = 0.1`/(
 s (-0.48466313872191963` + 0.5153368612780803` Sqrt[s] + s))

Finally, the Laplace inverse package was used to obtain the solution enter image description here

The solution is not so bad, but I am wondering is it possible to solve these kind of questions in original form without any assumptions. I do not know how to write this equation in the standard Volterra integral equation.

$\endgroup$
3
$\begingroup$

The nonlinear integral-differential equation in the question can be solved iteratively as follows. Begin with the expression in the question, but with 2/Sqrt[π] factored out of the second integral (because Simplify does not automatically remove constants from integrands).

eq1 = Simplify[0.282095` Integrate[Derivative[1][A11][k]/Sqrt[-k + t], {k, 0, t}] + 
    ((-1 + E^A11[t]) Derivative[1][A11][t])/(Sqrt[2] Sqrt[-1 + E^A11[t] - A11[t]]) == 
    0.5` (0.2` - 0.0433792711308264` Sqrt[-1 + E^A11[t] - A11[t]] + A11[t] - 
    0.015336865356479351` Integrate[Sqrt[1/(-k + t)] Derivative[1][A11][k], {k, 0, t}] 
    2/Sqrt[π]), 0 < k < t];

and solve it for A11'[t].

ap = Simplify[A11'[t] /. First@Solve[eq1, A11'[t]]
(* (0.03067377677953718 - 0.03067377677953718*E^A11[t] + 
   0.1414213562373095*Sqrt[-1. + E^A11[t] - 1.*A11[t]] + 
   (0.03067377677953718 + 0.7071067811865475*Sqrt[-1. + E^A11[t] - 
   1.*A11[t]])*A11[t] - 0.4111796229566854*Sqrt[-1. + E^A11[t] - 
   1.*A11[t]]*Integrate[A11'[k]/Sqrt[-k + t], {k, 0, t}])/(-1. + 1.*E^A11[t]) *)

The question further specifies that A11[0] == 0. Inserting this into ap yields

(Series[ap, {A11[t], 0, 0}, Assumptions -> A11[t] >= 0] /. t -> 0) // Normal
(* 0.1 *)

In other words, the corresponding value of A11'[0] is 0.1. Now, NDSolve could solve A11'[t] == ap without difficulty, were it not for the Abel integral, Integrate[A11'[k]/Sqrt[-k + t], {k, 0, t}]. So, let us approximate A11'[k] in the integral by A11'[0], use NDSolve to obtain a better approximation for A11'[k], and continue iterating until A11[k] converges. Define

int[n_, t_?NumericQ] := NIntegrate[sp[n - 1][k]/Sqrt[t - k], {k, 0, t}, 
    Method -> {Automatic, "SymbolicProcessing" -> False}]
apn[n_] = ap /. Integrate[A11'[k]/Sqrt[t - k], {k, 0, t}] -> int[n, t];

and iterate

tmin = 1/1000; sp[-1][t_] = .1;
Do[{s[n], sp[n]} = Quiet@NDSolveValue[{A11'[t] == 
  Piecewise[{{apn[n], t > tmin}}, 1/10], A11[0] == 0}, {A11, A11'}, {t, 0, 1}], {n, 0, 5}]

Fortunately, this process actually converges, and rapidly.

Join[{.1}, Table[s[n][1], {n, 0, 5}]]
(* {0.1, 0.0799404, 0.0885934, 0.0854804, 0.0864669, 0.0861837, 0.0862587} *)

Plot[{0.1 t, s[0][t], s[5][t]}, {t, 0, 1}]

enter image description here

Shown are the initial guess (blue), the result of the first iteration (tan), and the result of the sixth iteration (green). The entire computation takes only seconds.

$\endgroup$
  • $\begingroup$ Thank you, it is very interesting, but A11[0] == 0, not A11[0] == 1. The solution is correct. I think it is just a typo. $\endgroup$ – hesamaero May 5 '17 at 21:20
  • $\begingroup$ @hesamaero Yes, a typo, now corrected. Thanks for pointing it out, as well as for accepting the answer. By the way, your equation can be recast as a Volterra equation of the second kind coupled to a first order ODE. However, it is not clear to me that doing so would be helpful. $\endgroup$ – bbgodfrey May 5 '17 at 21:26

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.