How to create Right-Click ActionMenu at mouse position?

Question

I have a Grid and need to enable some actions on individual values. For this I want to use an ActionMenu that shows on right-click of the grid cell.

This should behave just as the normal right-click menu. On a selection being made the action would evaluate and the ActionMenu would disappear. On clicking anywhere off of the ActionMenu it would disappear.

I am stuck on the first part of showing the ActionMenu. I know I need to use CurrentValue["MousePosition"] to position it but am not certain how to do this or how to get it to disappear.

A minimal Grid example is below.

Grid@MapIndexed[
  EventHandler[
    #1,
    {{"MouseClicked", 2} :> 
      ActionMenu["Action List", {"Value" :> Echo@#1, "Index" :> Echo@#2}]}
    ] &,
  Partition[Range[4], 2],
  {2}
  ]

Ideas?

Answer 1

Both solutions are undocumented but I don't think they will go away. Menu/MenuItem are used internally for a long time and AttachedCell is a relatively new concept but many of new features use it. E.g. DateSetter[], suggestion toolbar, image tools, message stack preview, etc.

ContextMenu

Quite out of the box. One needs to remember to use KernelExecute for procedures which can not be performed by the FrontEnd. Also, MenuEvaluator must be set to Automatic or a specific name of the Kernel you want to use. Otherwise the FrontEnd will try to run the procedure and it will probably fail returning 'unknown packet dialog'. Why both are needed? I don't know.

Grid @ MapIndexed[
  Style[ #1, ContextMenu -> {
    MenuItem["Value", KernelExecute@Echo@#, MenuEvaluator -> Automatic], 
    MenuItem["Index", KernelExecute@Echo@#2, MenuEvaluator -> Automatic]
  }] &,
  Partition[Range[4], 2], {2}
]

Undocumented AttachedCell usage, more flexible

A small example:

menu = With[
     {ca := NotebookDelete@EvaluationCell[]}
  ,  MathLink`CallFrontEnd[ FrontEnd`AttachCell[
         EvaluationBox[]
       , Cell[ BoxData @ ToBoxes @ ButtonBar[
              {"Value" :> (ca; Echo@#1), "Index" :> (ca; Echo@#2)}
            , Appearance -> "Vertical"
         ]]
       , Center, Center, "ClosingActions" -> {"OutsideMouseClick"}
     ]]
] &


Grid @ MapIndexed[
  EventHandler[#1, {{"MouseClicked", 2} :> (menu[#, #2])}] &, 
  Partition[Range[4], 2], {2}]

For more examples with an AttachedCell search around.