6
$\begingroup$

I have:

Graphics[{
  GeometricTransformation[
    {Gray, Dashed, 
     Table[InfiniteLine[{k, 0}, {0, 1}], {k, -6, 6}],
     Table[InfiniteLine[{0, k}, {1, 0}], {k, -6, 6}],}, 
     RotationMatrix[π/6]]}, 
  Axes -> True, AxesStyle -> Bold, PlotRange -> 5]

which produces this image:

enter image description here

Can anyone share a suggestion how I might make this a full sheet of graph paper (8.5x11) to print out?

$\endgroup$
  • $\begingroup$ Change the 6s to 12s and the 5 to 10? $\endgroup$ – bill s May 1 '17 at 17:00
  • $\begingroup$ I think you need to make it clear how you expect to fill an 8.5 x 11 page with a square image. Also, what should be the distance between to ruled lines on the printed page? $\endgroup$ – m_goldberg May 1 '17 at 17:23
  • 1
    $\begingroup$ A large variety of printable graph paper is available online (free download). You may find an isometric graph paper, an isometric dot paper or a hypometric grid paper that suits your purpose. $\endgroup$ – LouisB May 1 '17 at 18:22
8
$\begingroup$

Here is some code that produces a PDF file that should print something close to what you describe.

letter = {612, 792}; (* postscript point size *)
a4 = {596 , 842};
θ = ArcTan[2, 3];
vlines = Table[GeometricTransformation[
    InfiniteLine[{0, 0}, {0, 1}],
    {RotationMatrix[θ], {k, 0}}], {k, -16, 16}];
hlines = Table[GeometricTransformation[
    InfiniteLine[{0, 0}, {1, 0}],
    {RotationMatrix[θ], {0, k}}], {k, -16, 16}];
img = Graphics[{Gray, Dashed, vlines, hlines},
   Axes -> True,
   AxesStyle -> {{Bold}, {Thick}},
   BaseStyle -> {FontSize -> 14},
   PlotRange -> {{-4, 4}, {-5, 5}},
   ImageSize -> letter];
Export["paper.pdf", img]

Some difference between your original code and this version are

  • define letter and a4 as paper sizes
  • change angle so the lines go through axis integers
  • apply different axis styles, just to see the effect
  • use BaseStyle to set the font size
  • use ImageSize to select either letter or a4
  • Export the image as a PDF

The above seems to work. That is, my PDF viewer recognizes the exported file as a letter size page. Here is what it looks like: enter image description here

$\endgroup$
  • $\begingroup$ Thanks for the help. There are some nice things in here to learn. $\endgroup$ – David May 3 '17 at 6:00

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.