0
$\begingroup$

I am trying to compute the following limit, which, tell me if I am wrong, should be 0 for beta->Infinity when z

 k[z_, beta_] = (Sinh[(1 - I)*Sqrt[beta/2]* z] - 
 2 z Sinh[((1 - I)/2)*Sqrt[beta/2]])/((1 - I)*
  Sqrt[beta/2] Cosh[((1 - I)/2)* Sqrt[beta/2]] - 
 2 Sinh[((1 - I)/2) Sqrt[beta/2]]);
 Limit[k[z, beta], beta -> Infinity]

How come I am not getting any output from Mathematica? With regard to the limit going to 0, please look at the following plot:

 Manipulate[Plot[Abs[k[z, beta]], {z, -1/2, 1/2}], {beta, 1, 10000000}]

Can we state the limit is 0 as the order of magnitude is decreasing?

$\endgroup$
  • $\begingroup$ Try this and see what happens k[z, beta] /. beta -> Infinity $\endgroup$ – zhk May 1 '17 at 14:28
  • $\begingroup$ If I specify a value for z say 1 the Limit is ComplexInfinity $\endgroup$ – george2079 May 1 '17 at 14:28
3
$\begingroup$

The limit is parameter dependent. Large z case:

Limit[k[z, beta], beta -> Infinity, Assumptions -> z > 1/2]

(* Out[117]= ComplexInfinity *)

Small z case:

Limit[k[z, beta], beta -> Infinity, 
 Assumptions -> 0 < z < 1/2]

(* Out[120]= 0 *)
$\endgroup$
  • $\begingroup$ does it work also for -1/2<z<0? $\endgroup$ – Andrea G May 2 '17 at 10:48
  • $\begingroup$ I actually ran your second limit and Mathematica didn't return any output and doesn't seem to work. Can it depend on the version? Im using 10.4.1.0 Student Edition $\endgroup$ – Andrea G May 2 '17 at 12:40
  • $\begingroup$ Yes, it might depend on version. It also could depend on speed of hardware and software, since some subcomputations have to be time constrained (so Limit will not hang). As for -1/2<z<0, I just tried it: In[3]:= Limit[k[z, beta], beta -> Infinity, Assumptions ->-1/2<z<0] Out[3]= 0 $\endgroup$ – Daniel Lichtblau May 2 '17 at 13:56
  • $\begingroup$ is there a way to remove the time constraint and try to get your same result for the one that I am not getting with my software/hardware? $\endgroup$ – Andrea G May 2 '17 at 15:23
  • $\begingroup$ No way to remove time constraints, that's all in internal code. And if the result depends on version then removing them would not change things. $\endgroup$ – Daniel Lichtblau May 2 '17 at 15:25
2
$\begingroup$

No, the limit is in general not zero:

<< NumericalCalculus`
Plot[ReIm@NLimit[k[z,beta], beta->Infinity, Terms->15], {z, -.8, .8},  PlotRange->All]

enter image description here

$\endgroup$
  • $\begingroup$ what about Manipulate[Plot[Abs[k[z, beta]], {z, -1/2, 1/2}], {beta, 1, 10000000}]? can we say the limit is 0 in z in the range of (-1/2,1/2)? $\endgroup$ – Andrea G May 1 '17 at 14:40
1
$\begingroup$

It actually appears to be zero for, Abs[z]<1/2 :

f[z_] := Limit[k[z, beta] , beta -> Infinity]
{#, f[#]} & /@ Range[-1, 1, 1/10]

{{-1, ComplexInfinity}, {-(9/10), ComplexInfinity}, {-(4/5), ComplexInfinity}, {-(7/10), ComplexInfinity}, {-(3/5), ComplexInfinity}, {-(1/2), 0}, {-(2/5), 0}, {-(3/10), 0}, {-(1/5), 0}, {-(1/10), 0}, {0, 0}, {1/10, 0}, {1/5, 0}, {3/10, 0}, {2/5, 0}, {1/2, 0}, {3/5, ComplexInfinity}, {7/10, ComplexInfinity}, {4/5, ComplexInfinity}, {9/10, ComplexInfinity}, {1, ComplexInfinity}}

It is zero for some complex z as well. Its not clear if the bound is Abs[z]<1/2 though.

This does not work BTW:

 Limit[k[z, beta] , beta -> Infinity, 
     Assumptions -> {Element[z, Reals], -1/2 < z < 1/2}]
$\endgroup$
  • $\begingroup$ I agree with the fact that the limit is 0, which is the result that I expected. May I ask you why we cannot get a global result, rather than computing it discretely as you do? I just ran your last line but Mathematica didn't return an outoput but the input itself. Isn't Assumptions a function for Refine, Integrate and Simplify? Why are you using it here? $\endgroup$ – Andrea G May 1 '17 at 15:06
  • $\begingroup$ I don't know. You may want to un-accept this. Maybe someone else will know a trick to get a general result. $\endgroup$ – george2079 May 1 '17 at 15:15
1
$\begingroup$

You can proof the result, -1/2<=z<=1/2, with a few transformations and then a series-expansion like that

 k[z_, ceta_] = (Sinh[(1 - I)*Sqrt[beta/2]*z] - 
     2 z Sinh[((1 - I)/2)*Sqrt[beta/2]])/((1 - I)*
     Sqrt[beta/2] Cosh[((1 - I)/2)*Sqrt[beta/2]] - 
     2 Sinh[((1 - I)/2) Sqrt[beta/2]]) //. Sqrt[beta/2] -> ceta

Terms with Exp[-ceta/2] disapear,since ceta -> Infinity

 k1[z_, ceta_] = (k[z, ceta] // TrigExpand // Together // 
    TrigToExp) /. E^(-ceta/2) -> 0 // Simplify

Do ComplexExpand of the real part. (You get exactly the same for the imaginary part.)

 se = Simplify[
      ComplexExpand[Re[k1[z, ceta]], TargetFunctions -> {Re, Im}], 
         Assumptions -> {z \[Element] Reals, ceta \[Element] Reals}] // 
         Expand

Do the series expansion and set Sin, Cos to Interval[{-1,1}]

 se2 = Series[se, {ceta, \[Infinity], 1}] // Normal // Expand

 se3 = (se2) /. Cos[_] -> Interval[{-1, 1}] /. 
 Sin[_] -> Interval[{-1, 1}] // FullSimplify // Factor // Expand

 (*    -(z/ceta) + (E^(-ceta (1/2 + z)) Interval[{-1, 1}])/ceta + (
      E^(2 ceta z - ceta (1/2 + z)) Interval[{-1, 1}])/ceta     *)

Here you see, with Limit ceta->Infinity the exponetial terms either go to 0 or they explode, depending on z

Limit goes to 0, if

 Reduce[-1/2 - z <= 0, z]

 (*   z >= -(1/2)   *)

and

 Reduce[2 z - (1/2 + z) <= 0, z]

 (*     z <= 1/2    *)
$\endgroup$
  • $\begingroup$ This is pretty much what Limit does. $\endgroup$ – Daniel Lichtblau May 3 '17 at 20:43
  • $\begingroup$ Not exactly. With Limit, you have to guess the convergence limits with the help of some other information. Here you get them directly and proofed to be the only one. $\endgroup$ – Akku14 May 4 '17 at 5:45

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.