Restricting the domain of the integration limit to be positive

Question

I am trying to put a restriction on the limit of integration. I tried "Assumptions->" and Assuming[(){Refine[]}], but it doesn't work.. The integral I have is the following:

Integrate[y,{v,p,1},{x,1.75p-0.75v,v},{y,1.75p-0.75v,x}]

which gives $-0.0638021+0.765625p-1.91406p^2+1.78646p^3-0.574219p^4$. It is also true that $0<p<v<1$. My problem here is that $1.75p-0.75v$ is a straight line and if I were to construct it on domain $[1,1]$ then it would cross the horizontal v-axis at point $[1,0]$ when $1.75p-0.75=0$ or $p=0.43$. So when I integrate and $p>0.43$ there is no problem because it does not cross the v-axis. However, when $p<0.43$ it does cross it and since it is bounded by zero from below the function right to the $v$ value at which it crosses the v-axis just becomes a straight line on top of the v-axis. So when I integrate I have to consider this segment as well which adds another integral. So I guess my ultimate question is this: is it possible to place a restriction on $p$ ? Say if $p>0.43$ then my function is of this form, because if $p<0.43$ I will actually have another function...

Would appreciate any help! Thanks.

Answer 1

The expression you want to consider under a condition is

cnd = 7/4 p - 3/4 v;

Also, currently your integration in v is from p to 1, so I assume that p<1. In case if p<0 and v>0 we have cnd<0, so this region may not contribute. Similarly, if p<0 and v<0 we still have Abs[p]>Abs[v] so that cnd<0 and this region may not contribute either. What remains is the region 1>p>0. In this case cnd>0 only as long as v<7/3 p, which means that in order to restrict to the region where cnd>0, all we need to do is reduce the upper integration border for v such that

result = Integrate[y, {v, p, Min[7/3 p, 1]}, {x, 7/4 p - 3/4 v, v}, {y, 7/4 p - 3/4 v, x}]

-(49/768) (p - Min[1, (7 p)/3])^3 (9 p - Min[1, (7 p)/3])

which is valid for any 1>p>0. It does look kind of interesting when you plot it:

Plot[result, {p, 0, 1}]

The kink happens at p=3/7, where the integral has its maximal value

result/.p->3/7

5/147

UPDATE

If you don't feel like doing all the work to consider the different regions yourself, you can of course add a HeavisideTheta step function to the integrand, which will set the integrand to zero whenever cnd<0:

result2 = Assuming[p \[Element] Reals, 
             Integrate[ 
                y HeavisideTheta[cnd]
             , {v, p, 1}, {x, 7/4 p - 3/4 v, v}, {y, 7/4 p - 3/4 v, x}]
          ]

(1/62208)49 (-81 (-1 + p)^3 (-1 + 9 p) HeavisideTheta[-1 + p] + HeavisideTheta[1 - p] HeavisideTheta[p] (1280 p^4 - (-3 + 7 p) (-27 + p (261 + p (-201 + 287 p))) HeavisideTheta[-1 + (7 p)/3]))

The result now looks a bit more complicated, but you can i.e. plot it and see that it describes exactly the same function as the previous one.

UPDATE 2

OK, if I understood your question correctly now, you want to actually set 7/4 p - 3/4 v to 0 whenever it gets negative. For this consider first integrating out x and y:

intv = Integrate[ y, {x, Max[7/4 p - 3/4 v, 0], v}, {y, Max[7/4 p - 3/4 v, 0], x}]

1/6 (v - Max[0, (7 p)/4 - (3 v)/4])^2 (v + 2 Max[0, (7 p)/4 - (3 v)/4])

Now only integration in v remains. We can split it into two subregions of integration:

intv1 = Assuming[v < 7/3 p, intv // FullSimplify]

49/192 (p - v)^2 (7 p - v)

and

intv2 = Assuming[v > 7/3 p, intv // FullSimplify]

v^3/6

Integrating the two subregions separately and summing the result:

result3 = Integrate[intv1, {v, p, Min[7/3 p, 1]}] + Integrate[intv2, {v, Min[7/3 p, 1], 1}]

-((147 p^4)/256) + 343/192 p^3 Min[1, (7 p)/3] - 245/128 p^2 Min[1, (7 p)/3]^2 + 49/64 p Min[1, (7 p)/3]^3 - 49/768 Min[1, (7 p)/3]^4 + 1/6 (1/4 - 1/4 Min[1, (7 p)/3]^4)

This time the plot of the function looks as follows

Plot[result3,{p,0,1}]

With maximum at p=0:

result3/.p->0

1/24

I hope now this is what you had in mind.