# how to neglect small terms for the variable going to infinity?

I have got an output which I would like to print out nicer, that is saying to Mathematica to neglect all terms small in beta. I was looking around but couldn't understand how to do it.

part1 = FullSimplify[
Abs[(1 - (1 - I)*(beta/2)^(1/2)*Exp[-(1 - I)/2*(beta/2)^(1/2)]*
Cosh[(1 - I) Sqrt[beta/2] z])*(dWNorm[x])] // ComplexExpand,
beta > 0];
dWNorm[x_] =
1/2 (Piecewise[{{(-c *(B1  Cos[B1 x] - B1  Cosh[B1  x]) -
B1  Sin[B1  x] - B1  Sinh[B1  x]), 0 <= x <= 1}}]);
B1 = 1.8751;
c = (Cos[B1] + Cosh[B1])/(Sin[B1] + Sinh[B1]);
integr1 = Integrate[part1, {x, -1, 1}, {z, -1/2, 1/2}];
fInf1 = TrigToExp[FullSimplify[beta/(16 integr1)]] // Chop

(*(0.15214 beta E^(
1.41421 Sqrt[beta]))/(-1. Sqrt[
beta] + (-2.82843 + 1. Sqrt[beta]) E^(1.41421 Sqrt[beta]) +
E^(0.707107 Sqrt[
beta]) ((0. + 1. I) Sqrt[
beta] (E^((0. - 0.707107 I) Sqrt[beta]) -
E^((0. + 0.707107 I) Sqrt[beta])) +
2.82843 (E^((0. - 0.707107 I) Sqrt[beta]) +
E^((0. + 0.707107 I) Sqrt[beta]))))*)


At this point, my wish is to neglect all small terms in beta, for beta goingto infinity. The desired output is:

 0.15214 Sqrt[beta]


If I use Series I get:

 Series[fInf1,{beta,Infinity,1}]//Normal

(*out=-((0.0537894 E^((1.41421 + 0.707107 I) Sqrt[beta]))/(Sqrt[1/
beta] (0.353553 E^((0. + 0.707107 I) Sqrt[
beta]) + ((0. - 0.353553 I) - 1. Sqrt[1/beta]) E^(
0.707107 Sqrt[
beta]) + ((0. + 0.353553 I) -
1. Sqrt[1/beta]) E^((0.707107 + 1.41421 I) Sqrt[
beta]) + (-0.353553 +
1. Sqrt[1/beta]) E^((1.41421 + 0.707107 I) Sqrt[beta]))))*)

• Series[....expression....,{beta,Infinity,1}] – yohbs Apr 19 '17 at 14:20
• @yohbs I did it but I am not getting the desired output. Also using Normal doesn't help. I still get a long expression involving imaginary units. – Andrea G Apr 19 '17 at 14:26

These computations can be reordered and simplified in a way that should be favorable. First note that the only x dependency is in dWNorm[x], so that integral with respect to x can be separate out. Also it is only nonzero for nonnegative x so there is no need to integrate over negative values and no need to define it as a piecewise function. Finally since it is independent of the other parameters it can be integrated numerically.

dWNorm[x_] = (-c*(B1 Cos[B1 x] - B1 Cosh[B1 x]) - B1 Sin[B1 x] -
B1 Sinh[B1 x])/2;
B1 = 1.8751;
c = (Cos[B1] + Cosh[B1])/(Sin[B1] + Sinh[B1]);
ixdWNorm = NIntegrate[Abs[dWNorm[x]], {x, 0, 1}]

(* Out[193]= 0.999997013172 *)


Now we can work on part1 keeping in mind we have already integrated over x.

ixpart1 =
Simplify[ComplexExpand@
Abs[(1 - (1 - I)*(beta/2)^(1/2)*Exp[-(1 - I)/2*(beta/2)^(1/2)]*
Cosh[(1 - I) Sqrt[beta/2] z])*(ixdWNorm)],
Assumptions -> {beta > 1000, -1/2 < z < 1/2}]

(* Out[186]= 0.999997013172 \[Sqrt](E^(-(Sqrt[beta]/Sqrt[
2])) (E^(Sqrt[beta]/Sqrt[2]) +
1/2 beta Cos[Sqrt[2] Sqrt[beta] z] +
1/2 beta Cosh[Sqrt[2] Sqrt[beta] z] -
Sqrt[2] Sqrt[beta] E^(Sqrt[beta]/(2 Sqrt[2]))
Cos[(Sqrt[beta] z)/Sqrt[2]] Cosh[(Sqrt[beta] z)/Sqrt[
2]] (Cos[Sqrt[beta]/(2 Sqrt[2])] +
Sin[Sqrt[beta]/(2 Sqrt[2])]) +
Sqrt[2] Sqrt[beta] E^(Sqrt[beta]/(2 Sqrt[2]))
Cos[Sqrt[beta]/(2 Sqrt[2])] Sin[(Sqrt[beta] z)/Sqrt[2]] Sinh[(
Sqrt[beta] z)/Sqrt[2]] -
Sqrt[2] Sqrt[beta] E^(Sqrt[beta]/(2 Sqrt[2]))
Sin[Sqrt[beta]/(2 Sqrt[2])] Sin[(Sqrt[beta] z)/Sqrt[2]] Sinh[(
Sqrt[beta] z)/Sqrt[2]])) *)


At this point it might make sense to replace the sine and cosine terms with 0 so that only terms increasing in beta will survive.

• how to replace 0? Can you show me the final output as the one I wrote I am expecting? – Andrea G Apr 19 '17 at 16:04

First, show that the imaginary part vanishes in this limit:

Limit[Chop@ComplexExpand@Im[fInf1], beta -> Infinity]
(* 0. *)


Then, use the fact that you know the order of the divergence, i.e. divide by Sqrt[beta] and look at the real part:

Limit[Chop@ComplexExpand@Re[fInf1/Sqrt[beta]], beta -> Infinity]
(* 0.15214 *)


Thus, for large beta your expression fInf1 goes like

0.15214 Sqrt[beta]