4
$\begingroup$

Given the matrices

$\gamma_{k}=\begin{bmatrix} O & -i\sigma_{k}\\ +i\sigma_{k}& O \end{bmatrix}$

where $\sigma_{k}$ is the $k^{th}$ Pauli matrix

$\gamma_{4}=\begin{bmatrix} I^{2} &0 \\ 0 & -I^{2} \end{bmatrix}$

$\gamma_{5}=\gamma_{1}.\gamma_{2}.\gamma_{3}.\gamma_{4}$

The anticommutator rule is defined by $\left [ x,y \right ]=xy+yx$

Show that the anticommutator relation $\gamma_{u}.\gamma_{v}+\gamma_{v}.\gamma_{u}=2\delta _{u v}I$ is satisfied for all $u,v=1,2,3,4$ where $I$ is the $4 \times 4$ identity matrix.

What I have defined is

\[ScriptCapitalO] = {{0, 0}, {0, 0}};
Subscript[\[Gamma], 1] = {{\[ScriptCapitalO], -I PauliMatrix[1]},
                         {I PauliMatrix[1], \[ScriptCapitalO]}};

Subscript[\[Gamma], 2] = {{\[ScriptCapitalO], -I PauliMatrix[2]}, 
                        {I PauliMatrix[2], \[ScriptCapitalO]}};

Subscript[\[Gamma], 3] = {{\[ScriptCapitalO], -I PauliMatrix[3]},
                          {I PauliMatrix[3], \[ScriptCapitalO]}};

Subscript[\[Gamma], 4] = {{IdentityMatrix[2], \[ScriptCapitalO]}, 
                          {\[ScriptCapitalO], -IdentityMatrix[2]}};

Subscript[\[Gamma], 5] = 
 Subscript[\[Gamma], 1].Subscript[\[Gamma], 2].Subscript[\[Gamma],3].Subscript[\[Gamma], 4];

One way to do this would be to show the identity holds individually. But this would be tedious. Can someone help me with a more efficient and general way to this?

$\endgroup$
1
  • $\begingroup$ Are you aware of ArrayFlatten[], BTW? $\endgroup$ Apr 8, 2017 at 11:56

1 Answer 1

6
$\begingroup$

Define DiracMatrix:

DiracMatrix[k_] /; k == 1 || k == 2 || k == 3 := 
  ArrayFlatten[{{0, - I PauliMatrix[k]}, {I PauliMatrix[k], 0}}]

DiracMatrix[4] := ArrayFlatten[{{ IdentityMatrix[2], 0}, {0, -IdentityMatrix[2]}}]

DiracMatrix[5] := Dot @@ Table[DiracMatrix[k], {k, 4}]

To prove the identity we could check e.g.

And @@ Flatten @ 
 Table[ DiracMatrix[i].DiracMatrix[k] + DiracMatrix[k].DiracMatrix[i]
        == 2 KroneckerDelta[i, k] IdentityMatrix[4], {i, 4}, {k, 4}]
True

sometimes one would prefer a visual test, something like e.g.

L[i_, k_] := DiracMatrix[i].DiracMatrix[k] + DiracMatrix[k].DiracMatrix[i] -
           2 KroneckerDelta[i, k] IdentityMatrix[4]
Table[ L[i, k] // MatrixForm, {i, 4}, {k, 4}] // MatrixForm
$\endgroup$
2
  • $\begingroup$ What is /; k == 1 || k == 2 || k == 3 Supposed to mean? $\endgroup$
    – Physkid
    Apr 9, 2017 at 11:55
  • $\begingroup$ This is Condition to ensure that the function DiracMatrix has appropriate values only for k equal to 1, 2, 3. See Consdition at documentation pages. $\endgroup$
    – Artes
    Apr 9, 2017 at 18:42

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.