In Mathematica 11.0, the following limit,

Limit[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], n -> ∞]

gave me an answer of $e^{6 \operatorname{arctanh}(1/7)}$, which equals 64/27, but in Mathematica 11.1, it doesn't give an answer. Anyone else experience this problem?

Granted, with Mathematica 11.1.0, this does work:

Limit[Power[RealAbs[((1 - 4 n)/(3 n + 2))^(3 n)], (n)^-1], n -> ∞]

Giving a correct answer of 64/27.

Update: Due to Anjan Kumer's suggestion, I tried:

Limit[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], 
  n -> \[Infinity]] // PowerExpand

But it gave an incorrect answer of $-64/27$.

Update #2: I believe there has been some editing to my question. This question arises when we are using the Root Theorem in calculus, which requires that we investigate $$\lim_{n\to\infty}\sqrt[n]{|a_n|}$$ in order to determine if the series $\sum_{n=1}^{\infty}a_n$ converges. Due to difficulties with Mathematica's Abs command over the years, and the fact that $\sqrt{x^2}=|x|$, we frequently use this fact to avoid difficulties. Thus, using the Root Test to determine the convergence of the series $$\sum_{n=1}^{\infty}\left(\frac{1-4n}{3n+2}\right)^{3n}$$ requires that we evaluate the limit: $$\lim_{n\to\infty}\sqrt[n]{\left|\left(\frac{1-4n}{3n+2}\right)^{3n}\right|}$$ Now, I made a mistake and used the absolute value bars in the Writing Assistant in my input. Now, I note that the following works and gives the correct answer (I am copying and pasting an image of my input and output).

enter image description here

Now, notice what happens when I try to use the fact that $\sqrt{x^2}=|x|$ (Again, I am copying and pasting an image of my input and output).

enter image description here

See, the exponent 2 is inside the Sqrt brackets, not outside. However, again a different answer.

  • $\begingroup$ Doesn't return any answer on MMA 11.1.0. You can get an answer by using PowerExpand. $\endgroup$ – Anjan Kumar Apr 6 '17 at 7:17
  • $\begingroup$ @AnjanKumar I tried PowerExpand, but it gave a wrong answer. See my update to my original post. $\endgroup$ – David Apr 6 '17 at 15:43
  • $\begingroup$ The function Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1] is complex-valued. Its limit as n approaches ComplexInfinity does not exist at all. $\endgroup$ – user64494 Apr 6 '17 at 18:38
  • 6
    $\begingroup$ This will be investigated. $\endgroup$ – Daniel Lichtblau Apr 7 '17 at 15:11
  • $\begingroup$ See also the discussion here: mathematica.stackexchange.com/questions/89054/… $\endgroup$ – Dimitris Apr 8 '17 at 0:13

I'm struggling to see what the question is, other than "Anyone else experience this problem?", which I guess comes down to, "Can others confirm this is a backslide and that I haven't messed up something?" There is a certain amount of noise surrounding the question: the initial mis-coding of the absolute value and the abuse of PowerExpand in particular. This makes it unclear to me whether more is being sought.


The OP has already noted that coding the source problem (n-th root test) with the usual absolute value Abs works:

Limit[Power[Abs[((1 - 4 n)/(3 n + 2))^(3 n)], (n)^-1], n -> ∞]
(*  64/27  *)

Here is another workaround.

 Series[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], {n, ∞, 1}],
 n -> Infinity]
(*  64/27  *)

And another, which perhaps is the best representation of the OP's intended computation bypassing Abs:

 Power[Sqrt[(((1 - 4 n)/(3 n + 2))^(3 n))^2], (n)^-1], 
 n -> ∞,
 Assumptions -> n > 0 && n ∈ Integers]
(*  64/27  *)

Problem with PowerExpand

PowerExpand willy-nilly combines the exponents, effectively assuming the bases are positive. That hypothesis is not true in this case, so the result is bogus (due to user error, not an error in Mathematica). Both the incorrect Sqrt[x]^2 and the correct Sqrt[x^2] replacements for Abs[x] for real x expand to the same expression, which has a limit of -64/27 at infinity:

Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1] // PowerExpand     (* Sqrt[x]^2 *)
Power[Sqrt[(((1 - 4 n)/(3 n + 2))^(3 n))^2], (n)^-1] // PowerExpand   (* Sqrt[x^2] *)
(*  (1 - 4 n)^3/(2 + 3 n)^3  *)

When PowerExpand is applied to Limit, first the limit returns unevaluated, its arguments are expanded, and then the limit it reevaluated and returns the (correct) limit of -64/27 for the expanded function.

Note that because the power Power[z, (n)^-1] is the principal value, the correct and incorrect substitutions for Abs[x] converge to the same value as n -> Infinity.

Mathematica graphics

The fakeabs form Sqrt[x]^2 zigzags because x = ((1 - 4 n)/(3 n + 2))^(3 n) alternates sign and therefore Sqrt[x] alternates real/imaginary.

fakeabs = ReIm@N@Table[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], {n, 150}];
realabs = ReIm@N@Table[Power[Sqrt[(((1 - 4 n)/(3 n + 2))^(3 n))^2], (n)^-1], {n, 150}];
limit = {ReIm[64/27]};    
ListLinePlot[{fakeabs, realabs, limit}, PlotMarkers -> Automatic, 
 Frame -> True, PlotRangePadding -> Scaled[.05], PlotRange -> All, 
 PlotLegends -> {HoldForm@fakeabs, HoldForm@realabs, HoldForm@limit}]

I suppose it is clear that this appears to be a backslide.

  • $\begingroup$ Michael, thanks for the help. A lot of useful comments in your answer that were extremely helpful. Because of your answer, I will be able to edit my notebook that I have written to help my calculus students with the Root Test. $\endgroup$ – David Apr 8 '17 at 17:47
  • $\begingroup$ @David You're welcome. I use the Sqrt[x^2] trick a lot, too. I guess I should start trying out RealAbs to see if it's just as good. (However, Abs[x] // ComplexExpand still expands to Sqrt[x^2].) $\endgroup$ – Michael E2 Apr 8 '17 at 18:24

Do ComplexExpand to get the right result (Using Version 8.0 )

   Limit[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1] // 
            ComplexExpand, n -> Infinity]

    (*  64/27   *)
  • 1
    $\begingroup$ Also works for 11.1.0, although a few minutes are required. $\endgroup$ – bbgodfrey Apr 7 '17 at 0:02

This has been fixed in 11.2:

Limit[Sqrt[(((1 - 4 n)/(3 n + 2))^(3 n))^2]^(1/n), n -> ∞]

Limit[(Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2)^(1/n), n -> ∞]

Limit[Abs[((1 - 4 n)/(3 n + 2))^(3 n)]^(1/n), n -> ∞]

(Mathematica 10)



NLimit[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], 
   n -> ∞] // Chop // Rationalize[#, .000001] &
(* 64/27 *)


Limit[Power[Sqrt[((1 - 4 n)/(3 n + 2))^(3 n)]^2, (n)^-1], 
   n -> ∞] // FullSimplify // Timing
(* {10.405267, 64/27} *)

Note that there are is no need for adding other built-in functions such as ComplexExpand, PowerExpand and the like.


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.