Configuration to limit time spent on formatting output

Question

A typical example: I type the expression

DumpSave["/some/path/dump.mx", something]

...and hit Shift-Enter.

Then the kernel goes off on a 15-minute evaluation.

Hmmm, that must have been a huge file. Let's see... Nope, it's only 250Mb!.

If I evaluate the same expression but suppress all output (by appending ; to it), the evaluation is over instantly.

IOW, pretty much all of that 15-minute wait was spent on formatting output that I didn't really need.

---

Output is always nice to have (which is why I'm not in the habit of always appending a ; to every expression I evaluate in the front end), but only as long as it doesn't take too much screen space, or take too long to format or print out.

Recent versions of Mathematica do a good job of limiting the output's screen footprint by default, which is great.

Is there something similar for limiting the time spent on formatting an evaluation's output?

Hopefully, one could override this limit as needed; e.g.

Block[{$MaxOutputFormattingTime = Infinity}, someExpression]

---

(I spent some time scanning options in the Options Inspector, unsuccessfully; what I'm looking for may very well be somewhere in there, but I was not able to spot it.)

Answer 1

Usually by the time the front end gets something, aborting or interrupting interactively is useless, so I won't suggest that. IF I suspect a problem beforehand, I would use Short or something similar. For the type of question you are posing, I would try the Villegas-Gayley pattern to inject a high priority DownValue into MakeBoxes, flagging on something useful like the ByteCount.

Module[{c=0,r,t=10000},
    MakeBoxes[e_,f___]/;c===0 := Block[{c=1,r},
        c=ByteCount[r=MakeBoxes[e,f]];
        If[c<t,r,MakeBoxes[Short@e,f]]
    ]
]

Table[1,{60}]
Table[1,{80}]

(*{1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1}*)

(*{1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,<<45>>,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1}*)

By request, here is another version that will shorten the output if TimeConstrained cuts off Rasterize after 1 second. The example writes 1000 graphic objects to the notebook, but with the modification to MakeBoxes, 930 of them are omitted, significantly speeding up the display.

Module[{c=True,r,t=1},MakeBoxes[e_,f___]/;c:=Block[{c=False,r},r=TimeConstrained[Rasterize[Unevaluated@e],t];If[r=!=$Aborted,MakeBoxes[e,f],MakeBoxes[Short@e,f]]]]
Graphics[{RGBColor @@ RandomReal[1, 3], Disk[RandomReal[{-5, 5}, 2], RandomReal[]]} & /@ Range[100], ImageSize -> 40*{5, 5}] & /@ Range[1000]
(*1000 pictures output similar to below, but 930 of them are omitted by Short*)