How to upload an image to the Stack Exchange Imgur account?

Question

This is not a duplicate of How to call Imgur API.

I tried to upload to imgur using its API, but (as my friends test) the API of imgur cannot be called in Chinese mainland. Then I found that halirutan has a technology to upload an image to imgur even without any account information via http://stackoverflow.com/upload/image. Now I can upload image to imgur by his function SEUploader`sendImage. Little pity is that he implemented it with Java code.

We can find his code here. I get nothing after researching his Java code. Can we do the same thing in pure Mathematica using new functions introduced in version 11.0 such as HTTPRequest, URLRead and so on?

Answer 1

Update on June 29th, 2020

Since API has changed, the new code is here:

getFKey[] := 
 First@StringCases[
   URLRead[HTTPRequest["https://stackexchange.com"]]["Body"], 
   "fkey: '" ~~ Shortest[fkey___] ~~ "'" :> fkey]
uploadImageSE[imagePath_] := 
 Module[{req}, 
  req = HTTPRequest[
    "https://mathematica.stackexchange.com/upload/image?method=json&\
https=true", <|Method -> "POST", 
     "Body" -> {"file" -> File[imagePath], "fkey" -> getFKey[]}|>];
  ImportString[URLRead[req]["Body"], "RawJSON"]["UploadedImage"]]

---

This is expected to work with jpg and png files. You need to input the path to image, just like an upload.

uploadImageSE[imagePath_] := 
 Module[{req}, 
  req = HTTPRequest[
    "http://stackoverflow.com/upload/image", <|
     
     "Body" -> {"image" -> <|"Content" -> File[imagePath], 
         "MIMEType" -> "image/png"|>}
     |>];
  StringCases[URLRead[req, "Body"], "http" ~~ __ ~~ ".jpg" | ".png"] //
    First]


uploadImageSE["/Users/xxx/Downloads/test.png"]
(*"http://i.stack.imgur.com/WD80b.png"*)

Remember to remove the double quotes before accessing.