How can I plot and find the area of this region?
$\begingroup$
$\endgroup$
Add a comment
|
3 Answers
$\begingroup$
$\endgroup$
Polar plots trickery
plot = Show[PolarPlot[{Sin[f], Sqrt[3] Cos[f]}, {f, 0, 2 Pi}],
RegionPlot[
Sin[ArcTan[x, y]] > Sqrt[x^2 + y^2] <
Sqrt[3] Cos[ArcTan[x, y]], {x, -2, 2}, {y, -2, 2}],
Epilog -> {Text[Style["II", 30], {1, -0.5}],
Text[Style["III", 30], {1, 0.5}],
Text[Style["reg", 30], {0.25, 0.3}]}]
The area of the bigger circle (let's call it region I) is composed of II, III and reg. So, the area of reg is the area of I diminished by the area of II and III (note the careful choice of angles):
a1 = Area[
CoordinateTransform["Polar" -> "Cartesian", {r, f}], {f, -Pi/2,
Pi/2}, {r, 0, Sqrt[3] Cos[f]}]
a2 = Area[
CoordinateTransform["Polar" -> "Cartesian", {r, f}], {f, -Pi/2,
0}, {r, 0, Sqrt[3] Cos[f]}]
a3 = Area[
CoordinateTransform["Polar" -> "Cartesian", {r, f}], {f, 0,
Pi/2}, {r, Sin[f], Max[Sin[f], Sqrt[3] Cos[f]]}]
(3 π)/4
(3 π)/8
1/12 (3 Sqrt[3] + 2 π)
Hence
reg = a1 - a2 - a3 // FullSimplify
1/24 (-6 Sqrt[3] + 5 π)
$\begingroup$
$\endgroup$
4
r = RegionIntersection[
Disk[{0, 1/2}, 1/2],
Disk[{Sqrt[3]/2, 0}, Sqrt[3]/2]
];
Area[r]
1/24 (-6 Sqrt[3] + 5 \[Pi])
rp = RegionPlot[r];
-
$\begingroup$ Could u show this solution with Wolfram | Alpha quer? $\endgroup$ Apr 1, 2017 at 2:05
-
3$\begingroup$ @BayasgalanDamdinsvren This is a site for showing how to use Mathematica, and not for W|A. Try community.wolfram.com $\endgroup$ Apr 1, 2017 at 2:09
-
$\begingroup$ @C. E. where is the Rho=Sin[Phi] and Rho=Sqrt[3]Cos[Phi] in your script? $\endgroup$ Apr 1, 2017 at 3:22
-
1$\begingroup$ @Bay, C. E. elected to directly represent the disks as regions instead of explicitly writing down their polar equations. $\endgroup$ Apr 1, 2017 at 9:57
$\begingroup$
$\endgroup$
Just for another way. Adding the area of the parts from the 2 circles:
sol = Solve[(x - Sqrt[3]/2)^2 + y^2 == 3/4 &&
x^2 + (y - 1/2)^2 == 1/4, {x, y}];
r1 = 1/2;
r2 = Sqrt[3]/2;
a1 = VectorAngle @@ (# - {0, 1/2} & /@ ({x, y} /. sol));
a2 = VectorAngle @@ (# - {Sqrt[3]/2, 0} & /@ ({x, y} /. sol));
area[r_, t_] := r ^2 (t - Sin[t])/2
res = Simplify[area[r1, a1] + area[r2, a2]]
yields:
1/24 (-6 Sqrt[3] + 5 π)
