Is there an easy way to extract data?Inverse function of Thread

Question

I want to learn some tips to deal data.
If i want connect two data with Rule.

a = Array[Sqrt, 10]; b = Array[Sin, 10];
Thread[a -> b]

Then i gets.

{1 -> Sin[1], Sqrt[2] -> Sin[2], Sqrt[3] -> Sin[3], 2 -> Sin[4], 
 Sqrt[5] -> Sin[5], Sqrt[6] -> Sin[6], Sqrt[7] -> Sin[7], 
 2 Sqrt[2] -> Sin[8], 3 -> Sin[9], Sqrt[10] -> Sin[10]}

I want to extract the result.That means an inverse function of Thread.

That isFun[Thread[a -> b]]->{a,b}.
I know a solution is a=d[[;;,1]];b=d[[;;,2]].
Is there a better?

Answer 1

You can use Thread a second time:

a = Array[Sqrt, 10]; b = Array[Sin, 10];
x = Thread[a -> b];

{aa, bb} = List @@ Thread[x, Rule];

aa === a
bb === b

True

True

Or a bit more concisely, but perhaps not in the spirit you seek:

{aa, bb} = Thread[List @@@ x];

Answer 2

You'll get lots of variants. I always use Part like in your example. However one way, different to above, admittedly not an "UnThread" is:

{a, b} = Transpose[x /. Rule -> List]