4
$\begingroup$

I'm trying to compute the following integral

integrand = (-2 (Log[2] - Log[1/t + t])^2)/(-1 + t^2)

Numerically integrating it gives the expected result

1/2*NIntegrate[integrand, {t, 0, 1}]
=> 1.0518
N[7/8*Zeta[3]]
=> 1.0518

However when I try to integrate it symbolically I get

1/2*Integrate[integrand, {t, 0, 1}]
=> 1/16 (\[Pi] (I \[Pi] + Log[4]) (\[Pi] + I Log[64]) + 14 Zeta[3])
N[%]
=> -0.658472 + 3.06993 I

It is interesting that Mathematica returns the correct result 14/16 Zeta[3] as part of its solution, but in addition it returns some strange imaginary terms, which I couldn't get rid of. What can I do so that Mathematica will compute this integral correctly?

Update: My version of Mathematica:

11.0.1 for Mac OS X x86 (64-bit) (September 21, 2016)

$\endgroup$
  • $\begingroup$ On 11.1.0, I get the same result from both ways. Btw, the result has a negative sign. $\endgroup$ – Anjan Kumar Mar 22 '17 at 23:14
  • $\begingroup$ Sorry, I missed the sign in the integrand. It fixed it now. $\endgroup$ – asmaier Mar 22 '17 at 23:46
  • $\begingroup$ With 11.0.1 for Mac OS X x86 (64-bit) (September 21, 2016) using either 1/2*Integrate[integrand, {t, 0, 1}, PrincipalValue -> True] or 1/2*Integrate[integrand, {t, 0, 1}, Assumptions -> 0 < t < 1] they evaluate to -((7*Zeta[3])/8). Note your "correction" is not the negative of the original integrand $\endgroup$ – Bob Hanlon Mar 23 '17 at 0:01
  • $\begingroup$ This seems to have shown up in 11.0.1, since version 11 gives the result (7 Zeta[3])/8 directly. Can you try Integrate[Log[(2 t)/(1 + t^2)]^2/(1 - t^2), {t, 0, 1}]? $\endgroup$ – J. M. will be back soon Mar 23 '17 at 1:17
  • $\begingroup$ @J.M. I tried your suggested integral and the result was 7/8*Zeta[3] . $\endgroup$ – asmaier Mar 23 '17 at 23:20
6
$\begingroup$

Specify a real-ish path:

1/2*Integrate[integrand, {t, 0, 1}, Assumptions -> 0 < t < 1]
(*  -((7 Zeta[3])/8)  *)

Or:

res = 1/2*Integrate[integrand, {t, 0, 1/2, 1}];  (* verrry looong expressssion *)
N[res, 16]
(* -1.0517997902646450 + 0.*10^-17 I *)
$\endgroup$
  • $\begingroup$ res//Simplify evaluates to -((7*Zeta[3])/8) as expected $\endgroup$ – Bob Hanlon Mar 23 '17 at 0:41
  • $\begingroup$ @BobHanlon Thanks, I didn't try that. It still takes a long time to evaluate, so I wasn't that keen to follow up on it. -- But, wow, it simplifies really fast! $\endgroup$ – Michael E2 Mar 23 '17 at 0:48
2
$\begingroup$
$Version

(*  "11.1.0 for Mac OS X x86 (64-bit) (March 16, 2017)"  *)

integrand = (2 (Log[2] - Log[1/t + t])^2)/(-1 + t^2);

intN = 1/2*NIntegrate[integrand, {t, 0, 1}]

(*  -1.0518  *)

This is the negative of the result that you show. However, a Plot shows that the integral should be negative.

Plot[integrand, {t, 0, 1}]

enter image description here

Finding the Cauchy principal value

int = 1/2*Integrate[integrand, {t, 0, 1}, 
   PrincipalValue -> True]

(*  -((7 Zeta[3])/8)  *)

int == intN

(*  True  *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.