6
$\begingroup$

I would like to add some markers on some cities on a map (smaller or bigger depending on the values each city has)

vals={GeoVariant[Entity["Country", "Spain"], "SimplifiedArea"] -> 11.1268, 
         GeoVariant[Entity["Country", "China"], "SimplifiedArea"] -> 10.7984, 
         GeoVariant[Entity["Country", "UnitedStates"], "SimplifiedArea"] -> 
          10.5992}
GeoRegionValuePlot[vals, GeoRange -> {{-60, 90}, {-170, 190}}]

This gives the plotenter image description here

I would like to add now a Disk with radius 3 on New York, a disk with radius 2 on Madrid and a disk with radius 5 on Bejin. Anyone can help me? Thanks

$\endgroup$

2 Answers 2

6
$\begingroup$

Combine plots using Show.If you search docs you can easily find many examples. Note I used GeoDisk just to show you it exists. But you could also use Disk and Epilog for example. Or GeoGraphics instead of GeoListPlot etc. - there are many ways. Also consider GeoBubbleChart.

vals={
    GeoVariant[Entity["Country","Spain"],"SimplifiedArea"]->11.1268,
    GeoVariant[Entity["Country","China"],"SimplifiedArea"]->10.7984,
    GeoVariant[Entity["Country","UnitedStates"],"SimplifiedArea"]->10.5992};

cit = {
    GeoDisk[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], 
    Quantity[300, "Kilometers"]], 
    GeoDisk[Entity["City", {"Madrid", "Madrid", "Spain"}], 
    Quantity[200, "Kilometers"]], 
    GeoDisk[Entity["City", {"Beijing", "Beijing", "China"}], 
    Quantity[500, "Kilometers"]]};

pl1=GeoRegionValuePlot[vals,GeoRange->{{-60,90},{-170,190}}];
pl2=GeoListPlot[cit,GeoRange->{{-60,90},{-170,190}}];
Show[pl1, pl2]

enter image description here

Here example without Show just with Epilog and regular Disk for just NYC:

GeoRegionValuePlot[vals, GeoRange -> {{-60, 90}, {-170, 190}}, 
    Epilog -> {Red, Opacity[0.5], Disk[Reverse[First[GeoPosition[
    Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]]], 10]}]

enter image description here

$\endgroup$
3
  • $\begingroup$ Thank you very much. have a nice day $\endgroup$ Mar 16, 2017 at 14:01
  • $\begingroup$ one think. The circle in the second method looks in a different perspective if I use different earth projections, i.e. , GeoProjection -> "WinkelTripel". do you know how to avoid this problem? thanks $\endgroup$ Mar 16, 2017 at 14:15
  • 1
    $\begingroup$ @GiorgioColangelo but this is why I told you about GeoDisk? $\endgroup$ Mar 16, 2017 at 15:45
1
$\begingroup$

An alternative approach: use GeoBubbleChart to generate the disks and use the primitives as Epilog:

bubbles = {Entity["City", {"NewYork", "NewYork", "UnitedStates"}] -> 3, 
   Entity["City", {"Madrid", "Madrid", "Spain"}] -> 2, 
   Entity["City", {"Beijing", "Beijing", "China"}] -> 5};

epilog = GeoBubbleChart[bubbles, 
    ColorFunction -> "GeographyHistogramGradient", 
    GeoBackground -> None][[1, 1]];

GeoRegionValuePlot[vals, GeoRange -> {{-60, 90}, {-170, 190}}, 
 Epilog -> {Opacity[.7], epilog}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.