How to select and delete all Output cells in multiple notebooks programmatically without needing to (manually) opening them?

How to define a hot key for deleting all Output cells within a notebook from that notebook?

  • $\begingroup$ Maybe some useful information here. $\endgroup$ Commented Nov 1, 2012 at 15:06
  • $\begingroup$ I think this is answered in the answers to this, as @b.gatessucks points out. $\endgroup$
    – acl
    Commented Nov 1, 2012 at 15:21
  • $\begingroup$ I assume you know about the delete all output cell option in the Cell menu? If so it should be straightforward to assign a key to this (cf @acl and @b.gatessucks)? But may be you want a non interactive option? $\endgroup$
    – chris
    Commented Nov 1, 2012 at 15:37
  • $\begingroup$ Actually the linked in the comments thread does not show simplest menu-wise solution. $\endgroup$ Commented Nov 1, 2012 at 15:41
  • 1
    $\begingroup$ Yes, you put it in $UserBaseDirectory. If the original is at $InstallationDirectory/foo/bar/file.tr, then you mirror the tree and copy it to $UserBaseDirectory/foo/bar/file.tr $\endgroup$
    – rm -rf
    Commented Nov 1, 2012 at 16:03

4 Answers 4


Without adressing the hotkey issue (you could add a menu entry, or simply put an appropriate Button in your notebook), here is one variety that uses NotebookDelete and can be modified to include different CellStyles as well. The first argument nb defines which notebook to work on, the second argument styles defines the styles of to-be-deleted cells:

CleanNotebook[nb_: SelectedNotebook[],styles_: {"Output"}] := 
   (NotebookFind[nb, #, All, CellStyle];
    NotebookDelete[nb];) & /@ styles

Together with NotebookOpen, NotebookSave and NotebookClose and related functions you should be able to work on arbitrary notebooks programmatically.


docpath = 
  ToFileName[{$InstallationDirectory, "Documentation", "English", 
    "System"}, "ExampleData"];

nb = NotebookOpen[ToFileName[docpath, "document.nb"]]

Mathematica graphics


Take care what other styles you choose, they´ll be gone for good...

Edit: You may also use the Option Visbible->False to supress the opening of a window for this notebook. This seems useful for batch processing (especially if Dynamic stuff is involved, because this will probably not trigger if invisible), but takes additional care to save and close programmatically because invisble windows do not show up in the menu bar.


doc = ToFileName[{$InstallationDirectory, "Documentation", "English", 
    "System", "ExampleData"}, "document.nb"];

bak = ToFileName[$TemporaryDirectory, "document_clean.nb"];

nb = NotebookOpen[doc, Visible -> False];
NotebookSave[nb, bak]

NotebookOpen[bak, Visible -> True];

There is still an issue with the Visible option being saved in the backup notebook and hiding when reopened (thus re-setting Visible->True).

  • $\begingroup$ Is that a typo that the second instance of SelectedNotebook[] should be nb? $\endgroup$
    – user13253
    Commented Nov 2, 2012 at 2:02
  • $\begingroup$ If i'm applying the function should the first argument be simply the file name (a _String expression) or that wrapped with NotebookOpen? $\endgroup$
    – user13253
    Commented Nov 2, 2012 at 2:32
  • $\begingroup$ @MonkeyKing: Correct! Fixed... $\endgroup$
    – Yves Klett
    Commented Nov 2, 2012 at 6:49
  • $\begingroup$ @MonkeyKing: If you use NotebookOpen it returns a NotebookObject. This NotebookObject can be used as a handle for subsequent actions. See edit. $\endgroup$
    – Yves Klett
    Commented Nov 2, 2012 at 6:57
  • $\begingroup$ If you use this method on many notebooks, wouldn't it cause many notebooks quickly open on your screen and close? Is there a way to open them for kernel but not visually to human? $\endgroup$
    – user13253
    Commented Nov 2, 2012 at 14:41

This is how you do it through menus, As correctly noted in the comment this is equivalent to the shortcut ALT+C >> L >> ENTER.

enter image description here

  • 2
    $\begingroup$ I find the keyboard shortcut Alt c l Enter much faster $\endgroup$ Commented Nov 1, 2012 at 19:19
  • $\begingroup$ @RolfMertig yes, noted in the post, thanks. $\endgroup$ Commented Nov 1, 2012 at 19:58
  • $\begingroup$ I'm using Alt-C UpArrow Enter, so I really hope that entry will stay the second to last in future versions :-) $\endgroup$ Commented Nov 1, 2012 at 21:46
  • 1
    $\begingroup$ What about in Mac? Alt+c types in ç for me. $\endgroup$
    – user13253
    Commented Nov 2, 2012 at 1:09

Update December 6th: There is an updated version (plus a bug fix for M9) working on Windows, MacOSX and Linux available and installable by


On Windows (Mac does not work yet): Execute the following code in a notebook and restart Mathematica.

Then hitting F4 will delete all Output, Print and Message cells in the selected notebook, while pressing F8 will do so in all open notebooks which are not Wolfram Documentation notebooks. This was more difficult to program than it should be ...

$OverWriteUserBaseDirectoryKeyEventTranslations = True;
       (* Delete all Output, Message and Print cells in the selected notebook *)
                 Item[KeyEvent[\"F4\"(*, Modifiers -> {\"Control\",\"Shift\"}*)], 
                   Module[{nb = SelectedNotebook[]},
                    Scan[Function[c, If[NotebookFind[nb, c, All, CellStyle, AutoScroll -> False] =!= $Failed,
                                    NotebookDelete[nb, AutoScroll -> False]]  
                     {\"Message\", \"Output\", \"Print\"}
            ], MenuEvaluator -> Automatic ],\n
  (* Delete all Output, Message and Print cells in all open notebooks *)
               Module[{nbs = Notebooks[]},
                Quiet[nbs = Select[nbs,  Function[z, Not[StringMatchQ[ Replace[ NotebookFileName[z], $Failed :> \"\"],
                    Scan[Function[c, If[NotebookFind[nb, c, All, CellStyle, AutoScroll -> False] =!= $Failed,
                                    NotebookDelete[nb, AutoScroll -> False]]  
                     {\"Message\", \"Output\", \"Print\"}
            ], MenuEvaluator -> Automatic ],";
  • $\begingroup$ How about including Undo option? Instead of NotebookDelete[..] use MathLink`CallFrontEnd[FrontEnd`SelectionAddCellTags[nb, {"$deleted"}]] and then just before the last command SelectionMove[..] insert this If[NotebookFind[nb, "$deleted", All, CellTags, AutoScroll -> False] =!= $Failed, MathLink`CallFrontEnd[FrontEnd`SelectionRemoveCellTags[nb, {"$deleted"}]]; FrontEndTokenExecute["Clear"]]; $\endgroup$
    – Vladimir
    Commented Apr 14, 2013 at 18:37

Yves Klett's answer is still pretty simple, but I thought I would add an alternative V9 solution using Cells

nb = EvaluationNotebook[]; (* change as desired *)
cells = Cells[nb, CellStyle -> {"Output"}];
CopyToClipboard @ NotebookRead @ cells; (* optional - saves cells for pasting *)

Beware: Pasting the cells back into the notebook will replace the current selection. It is not an "undo" command. It potentially could save an enormous amount of data, which you might not always want.

Here's a modification of Yves Klett's function CleanNotebook, with an improvement suggested by @CarlWoll:

deleteStyle[nb_: SelectedNotebook[], styles_: {"Output"}] :=
  With[{cells = Flatten[Cells[nb, CellStyle -> styles]]},
    (* CopyToClipboard@NotebookRead@cells; (*optional*) *)

Again, there's no "undo" for this, so be careful.

  • 2
    $\begingroup$ Cells[nb, CellStyle -> {"Input", "Output"}] selects both "Input" and "Output" cells, no need to use Map. $\endgroup$
    – Carl Woll
    Commented Aug 26, 2017 at 0:37
  • $\begingroup$ @CarlWoll Thanks. I didn't know that. $\endgroup$
    – Michael E2
    Commented Aug 26, 2017 at 11:51
  • 1
    $\begingroup$ The advantage of this approach (as compared to Yves Klett's) is that it won't open collapsed cell groups containing the cells to delete. But for some reason it is much slower and requires more memory (taken by the FrontEnd) even without CopyToClipboard. On a Notebook of size 252 Mb the Yves Klett's CleanNotebook[] takes 2.5 sec to evaluate and the FrontEnd takes 1.88 Gb of memory ("Private Set" according to Windows Task Manager), but deleteStyle[] takes 64.2 sec to evaluate and the FrontEnd takes 2.43 Gb of memory (fresh session). $\endgroup$ Commented Aug 26, 2017 at 13:50
  • $\begingroup$ (OS Windows 7 x64, Mathematica 11.1.1) $\endgroup$ Commented Aug 26, 2017 at 13:55
  • 1
    $\begingroup$ I'm very surprised both by wonderful efficiency of the NotebookFind + NotebookDelete approach and disappointing performance of the Cells + NotebookDelete approach... $\endgroup$ Commented Aug 26, 2017 at 14:04

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.