Rotate an area between curves around the y axis

I'm struggling to figure out how to do this in Mathematica and really need some help. I'm pretty new to mathematica... I need to plot the solid of revolution obtained by rotating the region enclosed by the graphs of

x^2=y-2 ,2y-x-2=0 , x=0 , x=1

around y=3.... So far, I tried this :

 Show[RevolutionPlot3D[(x + 2)/2 - (x^2 + 2), {x, 0, 1}, PlotTheme -> "Classic", RevolutionAxis -> {1, 0, 0}]


But I'm not having what I need, it's not "filled"... The volume resulting of the revolution should be 51pi/20 (if it's useful) ... Thank you in advance

Update

On the basis of discussion in comments:

Integrate[r, {t, 0, 2 Pi}, {z, 0, 1}, {r, z^2 - 1, (z + 2)/2 - 3}]
RegionPlot3D[(x^2 - 1)^2 < y^2 + z^2 < ((x + 2)/2 - 3)^2, {x, 0,
1}, {y, -3, 3}, {z, -3, 3}, Mesh -> None, PlotStyle -> Opacity[0.5],
BoxRatios -> Automatic, Boxed -> False, Axes -> False,
Background -> Black]


I am not sure I have correctly interpreted the aim and I am unsure what the "answer" is (volume,surface area etc). However, I post this in caseitmay motivate the desired answer:

The solid of revolution can be plotted (with less than ideal cosmetic result) usingRegionPlot3D:

RegionPlot3D[
0 <= x^2 + y^2 <= 1 &&
1/2 (2 + Sqrt[x^2 + y^2]) <= z <= 2 + x^2 + y^2, {x, -1, 1}, {y, -1,
1}, {z, 1, 4}, PlotPoints -> 50, Mesh -> None, Background -> Black,
Boxed -> False, Axes -> False, PlotStyle -> Opacity[0.6],
PerformanceGoal -> "Quality"]


A more pleasing cosmetic result can be done by just plotting bounding surfaces:

p = {u Cos[v], u Sin[v], u^2 + 2};
c = { Cos[v], Sin[v], u};
l = {u Cos[v], u Sin[v], (u + 2)/2};
Show[ParametricPlot3D[l, {u, 0, 1}, {v, 0, 2 Pi}, Mesh -> None],
ParametricPlot3D[p, {u, 0, 1}, {v, 0, 2 Pi}, Mesh -> None],
ParametricPlot3D[c, {u, 3/2, 3}, {v, 0, 2 Pi}, Mesh -> None,
PlotStyle -> Opacity[0.7]], PlotRange -> {0, 3},
Background -> Black, Boxed -> False, Axes -> False]


Calculating the volume usingImplicitRegion:

vol = Volume[
ImplicitRegion[
0 <= x^2 + y^2 <= 1 &&
1/2 (2 + Sqrt[x^2 + y^2]) <= z <= 2 + x^2 + y^2, {{x, -1,
1}, {y, -1, 1}, {z, 1, 3}}]]


Calculating the volume using integration of cylindrical coordinates:

int = Integrate[
Det[D[{r Cos[t], r Sin[t], z}, {{r, t, z}}]], {r, 0, 1}, {t, 0,
2 Pi}, {z, (r + 2)/2, r^2 + 2}]


• Thanks a lot, the result obtained by plotting bounding surfaces seems to be what I need but isn't the surface revolving around the y axis... Thank you so much anyway, I will try to make il revolve around the x axis – Sebastien Martinez Mar 5 '17 at 13:50
• @SebastienMartinez that should just be a matter of permitting the parametric definition to desired aim. Good luck. Sorry for misreading axis:) – ubpdqn Mar 5 '17 at 13:52
• Yep, no problem ;) So I guess that I have to change"p", "c" and "l" ? – Sebastien Martinez Mar 5 '17 at 14:02
• @SebastienMartinez yes. You know what you are after. Adjust, test, readjust till write and along the way you get insight into Mathematica. It is midnight in my TZ so I am off to sleep:) – ubpdqn Mar 5 '17 at 14:05
• NIce ! Thanks a lot, good night :) – Sebastien Martinez Mar 5 '17 at 14:13