0
$\begingroup$
highP6 = D[y[t], {t, 3}] - Power[(Cos[t]), 3]*y[t] == 0;
ic1 = y[0] == a;
ic2 = y'[0] == -a;
ic3 = y''[0] == 0;
DSolve[{highP6, ic1, ic2, ic3}, y[t], t]

I cannot get the solution using the above code? Any help!

$\endgroup$
  • 3
    $\begingroup$ LOTS of DE do not have closed form solutions. If you could assign a constant value to 'a' then you could use NDSolve. $\endgroup$ – Bill Mar 3 '17 at 3:05
2
$\begingroup$

Since this is variable coefficient ODE, you can try series solution. The analytical series solution will be accurate "near" the point of expansion, which has to be where the initial conditions are. More terms makes it more accurate.

ClearAll[y,t,a];
nTerms=10;
pt=0;
ic={y[0]->a,y'[0]->-a,y''[0]->0};
ode=y'''[t]- Cos[t]^3 y[t];
s0=Series[ode,{t,pt,nTerms}];
s0=s0/.ic;
roots=Solve@LogicalExpand[s0==0];
s1=Series[y[t],{t,pt,nTerms+2}];
sol=Normal[s1]/.ic/.roots[[1]]

Mathematica graphics

Compare to Numerical

a=1;
nSol=NDSolve[{ode==0,y[0]==a,y'[0]==-a,y''[0]==0},y,{t,0,2}];
Plot[{sol/.a->1,Evaluate[y[t]/.nSol]},{t,0,2},
     PlotStyle->{Red,Blue},PlotLegends->{"Series","Numerical"}]

Mathematica graphics

Reference: solving-a-second-order-non-linear-differential-equation

|improve this answer|||||
$\endgroup$
  • $\begingroup$ I have proposed a SE site for maple, if you could help out to make it a success? area51.stackexchange.com/proposals/107315/maple $\endgroup$ – zhk Mar 3 '17 at 9:37
  • $\begingroup$ @MMM I added my self there. But this was done before few years ago, and due to lack of interest, the proposal was removed. There is simply not as many Maple users as Mathematica around. $\endgroup$ – Nasser Mar 3 '17 at 9:42
  • $\begingroup$ Thanks for your interest. I will try my best. I am sharing it with people. You do too, please. $\endgroup$ – zhk Mar 3 '17 at 9:44
  • $\begingroup$ Ask a random easy question, please. $\endgroup$ – zhk Mar 3 '17 at 9:45
2
$\begingroup$

Comment

Like Mathematica, Maple is also unable to solve the ode.

restart;
ode:=diff(y(t),t$3)-cos(t)^3*y(t)=0;
dsolve(ode);

enter image description here

DESol is a data structure to represent the solution of a differential equation.

|improve this answer|||||
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.