Selecting list entries with a True False index list of similar length [duplicate]

Question

I would like to determine which elements in a list are divisible by a specific number, lets say 3.

I generate a list with numbers:

numbers = Range[10];

I then use Divisible to create another list of equal length that has True and False entries related to whether or not the entry in numbers are divisible by 3:

In[1] := test = Divisible[numbers, 3]
Out[1] := {False, False, True, False, False, True, False, False, True, False}

The resulting list test thus acts as an index.

How would I go about adding all the items in numbers to a new list if their corresponding item in test is True?

Answer 1

Pick does exactly what you need:

numbers = Range[10];
test = Divisible[numbers, 3];
Pick[numbers, test]

{3, 6, 9}

Answer 2

you can use Select without having to create the list of Boolean values True, Falseexplicitly

Select[Range[10], Divisible[#, 3] &]
(* {3,6,9} *)

Alternatively one can use Extract

Extract[#, Position[Mod[#, 3], 0]] &@Range[10]

Cases can also be used

Cases[Range[10], _?(Mod[#, 3] == 0 &)]

using Patterns

Range[10] /. x_ /; ! Mod[x, 3] == 0 :> Sequence[]

using Part

Range[10][[3 ;; ;; 3]]

there are many ways you can use to get the answer in Mathematica.