1
$\begingroup$

I have a function with two variables (s,t):

 AT = 0.0000792456 E^((0.08636 - 0.141381 t + 
 0.0169775 (-0.282843 + Sqrt[0.08 + t])) (73.3877 + 
 Log[s])) s (-0.212432 + 0.990813 (73.3877 + Log[s])) + 
 4.2148 E^(-2.13198 t) s^(0.875076 - 1.06027 t + 
 1.07567 (-0.282843 + Sqrt[0.08 + t])) Sin[
 1/2 \[Pi] (0.875076 - 1.06027 t + 
 1.07567 (-0.282843 + Sqrt[0.08 + t]))]

and I have to obtain the next definite integral:

Integrate[AT, {t, 0, 1}]

which will be a function of s, but Mathematica does not calculate this integral, and I obtain the input expression after evaluation:

enter image description here

How can I solve this problem?

$\endgroup$
  • $\begingroup$ I suspect that a numerical integral is the best that you can do, but applying assumptions about the value of s (e.g. s>0 might help) $\endgroup$ – mikado Feb 26 '17 at 22:03
3
$\begingroup$

If you are satisfied with a ParametricFunction object, you could use:

sol = ParametricNDSolveValue[{f'[t] == AT, f[0] == 0}, f[1], {t,0,1}, s];

The output is a ParametricFunction that gives you the value of the integral for a given value of s. For example, you can plot it:

Plot[sol[s],{s,0,1}]

enter image description here

Compare to evaluating the definite integral numerically:

Block[{s = .3}, NIntegrate[AT, {t, 0, 1}]]
sol[.3]

0.692984

0.692984

$\endgroup$
2
$\begingroup$

You could do this numerically:

f[ss_] := NIntegrate[AT /. s -> ss, {t, 0, 1}]
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.