define a function with optional arguments

Question

I have defined a function as follows:

fDistance[pointA_, pointB_: {0, 0}, metric_: "taxi"] := 
 Module[{interval}, 
  If[metric == "taxi", 
   interval = 
    Abs[pointB[[1]] - pointA[[1]]] + Abs[pointB[[2]] - pointA[[2]]], 
   interval = 
    Sqrt[(pointB[[1]] - pointA[[1]])^2 + (pointB[[2]] - 
        pointA[[2]])^2]]; interval]

Then

fDistance[{3, 4}]
(*7; ok*)

fDistance[{3, 4}, {1, 2}, "euclid"]
(*2 Sqrt[2]; ok*)

But

fDistance[{3, 4}, "euclid"]
(*error message*)

How can I avoid that Mathematica assign the string literal 'euclid' to the variable pointB? It should have returned 5 as the output below shows

fDistance[{3, 4}, {0, 0}, "euclid"]
(*5*)

And as a second question: Is it possible to call the function in the following manner

fDistance[pointB={1, 2}, metric='normal', pointA={3, 4}]

that is, its arguments are paired with a keyword instead of being in the correct order according to the function denition?

Thank you very much.

Answer 1

You must add a restricting pattern to the second parameter. Define your function like this:

fDistance[pointA_, pointB : {_, _} : {0, 0}, metric_: "taxi"] := (* rest of code *)

fDistance[{3, 4}, "euclid"]

5

Recommended reading:

• How can I create a function with "positional" or "named" optional arguments?
• How to Combine Pattern Constraints and Default Values for Function Arguments
• Can I make a default for an optional argument the value of another argument?
• A question about two ways to use Default

---

For your second point you should first familiarize yourself with:

• Guide: Options Management
• Tutorial: Manipulating Options
• Functions with Options

Then return to the first link in this post for how this will relate to default arguments.

As a brief example of setting up your function to use only named options:

ClearAll[fDistance]

Options[fDistance] =
  {"pointA" -> {0, 0}, "pointB" -> {0, 0}, "metric" -> "taxi"};

fDistance[OptionsPattern[]] := Module[{pointA, pointB, metric},
  {pointA, pointB, metric} = OptionValue[{"pointA", "pointB", "metric"}];
  If[metric == "taxi", 
    Abs[pointB[[1]] - pointA[[1]]] + Abs[pointB[[2]] - pointA[[2]]], 
    Sqrt[(pointB[[1]] - pointA[[1]])^2 + (pointB[[2]] - pointA[[2]])^2]
  ]
]

fDistance[]
fDistance["pointA" -> {3, 4}]
fDistance["metric" -> "euclid", "pointA" -> {3, 4}]

0

7

5

This may also be of use and/or interest to you:

• Functions with changeable global variables