0
$\begingroup$
Solve[1 - ((1 + x^α)^(-β θ) (1 + θ + β θ Log[1 + x^α]))/(1 + θ) == p, x]

Solve cannot solve this equation. Note that β, θ, α and x are all positive but I don't know how to implement that in the Solve function.

$\endgroup$
2
  • 1
    $\begingroup$ I am not sure if you can find an analytic result for $x$ but you can surely find a numerical result for $x$ by using FindRoot or NSolve. $\endgroup$ Feb 25, 2017 at 14:28
  • $\begingroup$ @Ahmed Abo-Zaid can you please modify your question so it is clear what equation you are trying to solve. Otherwise your question may not help others in future $\endgroup$
    – Ali Hashmi
    Feb 27, 2017 at 18:12

2 Answers 2

3
$\begingroup$

It is best to see what happens on the Plot

α := 5;
θ := 5;
β := 5;
p := 1;
eq = 1 - ((1 + x^α)^(-β θ) (1 + θ + β*θ Log[1 + x^α]))/(1 + θ)-p

Plot[eq, {x, -1, 1}]

enter image description here

Using FindInstance

sol1 = FindInstance[eq == 0, x, Reals, 5]
(*{{x -> -((-1 + E^(6/25))^(1/5)/E^(6/125))}}*)
sol2 = FindInstance[eq == 0, x, Complexes, 5]
(*{{x -> (-1 + 1/E^(6/25))^(
1/5)}, {x -> -(-1)^(1/5) (-1 + 1/E^(6/25))^(1/5)}, {x -> (-1)^(
2/5) (-1 + 1/E^(6/25))^(
1/5)}, {x -> -(-1)^(3/5) (-1 + 1/E^(6/25))^(1/5)}, {x -> (-1)^(
4/5) (-1 + 1/E^(6/25))^(1/5)}}*)

FindRoot Needs a good starting point.

 FindRoot[eq, {x, -0.8}]
 (*{x -> -0.734222}*)

NSolve It is better, but in some cases.

NSolve[eq == 0, x]// TableForm
(*{
{x -> -0.734222},
{x -> -0.226887 - 0.698287 I},
{x -> -0.226887 + 0.698287 I},
{x -> 0.593998 - 0.431565 I},
{x -> 0.593998 + 0.431565 I}
}*)

You can also use:

 NSolve[{eq == 0, -2 < x < 2}, x]
 {{x -> -0.734539}}
 (*Only find reals solution*)
 NSolve[{eq == 0, -1 < x < 0}, x]
 NSolve[{eq == 0, -2 < x < 0}, x]

Symbolic solution.

Using powerfull Maple, it seems can solve :P enter image description here where:

$\{\text{$\_$Z7}\in \mathbb{Z},\text{$\_$Z8}\in \mathbb{Z}\}$

with: z7=0 only exists solutions.

 z7 = 0;
 x = Exp[(Log[(Exp[(-ProductLog[z7, (1 + θ)*(p - 1)*Exp[-1 - θ]] - 1 - θ)/(β*θ)] - 1)] + 2*I*Pi*z8)/α]

$$x=\exp \left(\frac{\log \left(\exp \left(\frac{-W_{\text{z7}}((1+\theta ) (p-1) \exp (-1-\theta ))-1-\theta }{\beta \theta }\right)-1\right)+2 i \pi \text{z8}}{\alpha }\right)$$

 Table[x // N, {z8, 0, 5}] // Chop // TableForm
 (*{
 {0.593998 + 0.431565 I},
 {-0.226887 + 0.698287 I},
 {-0.734222},
 {-0.226887 - 0.698287 I},
 {0.593998 - 0.431565 I},
 {0.593998 + 0.431565 I}
 }*)
$\endgroup$
2
  • $\begingroup$ thanks, it seems that no escape from numerical solutions. $\endgroup$ Feb 26, 2017 at 19:11
  • $\begingroup$ @AhmedAbo-Zaid . Last equation is symbolic solution.Remove //N and //Chop symbols from Table. $\endgroup$ Feb 26, 2017 at 21:34
1
$\begingroup$

A numerical solution is possible, I gave some arbitrary values to parameters that you can change ;

FindRoot[1 - ((1 + x^\[Alpha])^(-\[Beta] \[Theta]) (1 + \[Theta] + \[Beta] \
\[Theta] Log[1 + x^\[Alpha]]))/(1 + \[Theta]) == p /. \[Alpha] -> 5 /. \[Beta]-> 5 /. \[Theta] -> 5 /. p -> 1, {x, 0.5}]

It gives

{x -> 2.30848}
$\endgroup$
0

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.