2
$\begingroup$

In the wake of my solution to discussion of the problem of summation of Legendre polynomials (https://math.stackexchange.com/questions/2111566/summation-of-legendre-polynomials-sum-l-2-infty-frac2l1l1kl1/2116383#2116383) I stumbled upon the following problem which has interesting aspects.

Consider the sum

$$f_{-2}(z)=\sum _{n=1}^{\infty } \frac{P_n(z)}{n^2}$$

fm2[z_] := Sum[LegendreP[n, z] 1/n^2, {n, 1, \[Infinity]}]

The problem:

  1. Find a closed form expression
  2. Discuss the functions appearing

Hint: consider the sum

$$g(p,z) = \sum _{n=0}^{\infty } p^n P_n(z)$$

g[p_,z_]:=Sum[LegendreP[n, z] p^n, {n, 0, \[Infinity]}]

EDIT #1

Equivalent formulation of the problem

As shown in §2 of my solution the problem is equivalent to solving the integral

$$fi_{-2}(z) = \int_0^1 \frac{1}{q} \log \left(\frac{2}{\sqrt{q^2-2 q z+1}-q z+1}\right) \, dq$$

for $-1 < z < 1$.

$\endgroup$
  • $\begingroup$ would you mind accepting my answer? $\endgroup$ – Andreas 23 hours ago
2
$\begingroup$

This will be a step-by-step solution which gives the reader the opportunity to continue at some intermediate result.

§1. First of all we rule out that the problem is trivial by letting Mathematica calculate the infinite sum

Assuming[-1 < z < 1, Sum[LegendreP[n, z] 1/n^2, {n, 1, \[Infinity]}]];

It is returned unevaluated immediately.

Also consulting some of the literature showed no result for this sum. E.g. http://functions.wolfram.com/Polynomials/LegendreP/23/02/, http://www.ucl.ac.uk/~ucahdrb/MATHM242/OutlineCD2.pdf

§2. In order to solve the problem we start with a straightforward approach which, however, leads to an integral which Mathematica cannot solve. This is then the next step of the problem which is herewith also presented for the community to be solved.

Starting from the hint we find the generating function of the Legendre-Polynomials:

g[p_, z_] = Sum[LegendreP[n, z] p^n, {n, 1, \[Infinity]}]

(* Out[1686]= -1 + 1/Sqrt[1 + p^2 - 2 p z] *)

The inverse square under the sum can be generated by twofold Integration thus

Assuming[n > 0, Integrate[1/q Integrate[p^(n - 1), {p, 0, q}], {q, 0, 1}]]

(* Out[1684]= 1/n^2 *)

Now we only have to apply this integration procedure to g.

First the p-integral:

ip = Assuming[{0 < q < 1, 0 < z < 1}, Integrate[1/p g[p, z], {p, 0, q}]]

(* Out[1697]= Log[2/(1 - q z + Sqrt[1 + q^2 - 2 q z])] *)

now the q-integral

ipq = Assuming[{0 < z < 1}, Integrate[1/q ip, {q, 0, 1}]];

$$\int_0^1 \frac{\log \left(\frac{2}{\sqrt{q^2-2 q z+1}-q z+1}\right)}{q} \, dq$$

Unfortunately, this integral is returned unevaluated; also the antiderivative cannot be determined:

Assuming[{0 < z < 1}, Integrate[1/q ip, q]]

(* Out[1699]= \[Integral]Log[2/(1 - q z + Sqrt[1 + q^2 - 2 q z])]/q \[DifferentialD]q *)

And this is just what makes the problem interesting!

We therefore put this integral as an edit into the question as an equivalent problem.

In order to get a feeling for the sum let us first try specific values of z:

fm2m1 = Assuming[{z == -1}, Integrate[1/q ip, {q, 0, 1}]]

(* Out[1710]= -(\[Pi]^2/12) *)

fm20 = Assuming[{z == 0}, Integrate[1/q ip, {q, 0, 1}]]
% // N

(* Out[1714]= 1/6 (-\[Pi]^2 - 3 Log[2]^2 - Log[8] Log[-1 + Sqrt[2]] + 
   3 Log[-1 + Sqrt[2]]^2 - 6 PolyLog[2, 1 - Sqrt[2]] + 
   6 PolyLog[2, 2 - Sqrt[2]]) *)

(* Out[1715]= -0.107492 *)

fm21 = Assuming[{z == 1}, Integrate[1/q ip, {q, 0, 1}]]

(* Out[1712]= \[Pi]^2/6 *)

Numerically the original function is equivalent to

fm2n[z_] := NIntegrate[1/q ip, {q, 0, 1}]

The graph (together with the specific values just calculated) is

Plot[{fm2n[z], fm2m1, fm20, fm21}, {z, -1, 1}, 
 PlotStyle -> {Bold, Dashed, Dashed, Dashed}, 
 PlotLabel -> 
  "The function \!\(\*SubscriptBox[\(f\), \(-2\)]\)(z) \[LongEqual] \
\!\(\*UnderoverscriptBox[\(\[Sum]\), \(n = 1\), \
\(\[Infinity]\)]\)\!\(\*FractionBox[TemplateBox[{\"n\",\"z\"},\n\
\"LegendreP\"], SuperscriptBox[\(n\), \(2\)]]\) ", AxesLabel -> {"z", ""}]

enter image description here

EDIT 12.05.17

Unser tangh2014 pointed out in a comment that the sum has a closed form if for $n>1$ we approximate $n^2$ by $n^2-1$ in the denominator.

The approximate sum is then

$$f_{-2a}(z)=\sum _{n=2}^{\infty } \frac{P_n(z)}{n^2-1}+P_1(z)$$

Decomposing the denominator into partial fractions, writing the inverse powers as integrals, using the generating function (now starting at $n=2$), the final integration can be done in closed form with the result

$$f_{-2a}(z)=\frac{1}{4} \left(-2 \sqrt{2-2 z}+z (\log (4)-1)-2 z \log \left(-z+\sqrt{2-2 z}+1\right)-2 \log \left(\frac{z-\sqrt{2-2 z}-1}{z-1}\right)+4\right)$$

The comparison in the plot shows reasonable qualitative agreement

enter image description here

The quatitative agreement is poor close to $z = 0.1$ as can be seen from the graph

enter image description here

| improve this answer | |
$\endgroup$
  • $\begingroup$ If approximate $1/n^2$ as $1/(n^2-1)$, we can get a closed form expression. $\endgroup$ – tanghe2014 May 10 '17 at 13:41
  • $\begingroup$ @tanghe2014 Yes, but this is a trivial case as you can see if you make the same repacement in the Zeta-function: Sum[1/(n^2 - 1), {n, 2, [Infinity]}] = 3/4 $\endgroup$ – Dr. Wolfgang Hintze May 10 '17 at 16:11
  • $\begingroup$ Yes, but it gives us an approximate result in closed form for $\sum _{n=1}^{\infty } \frac{P_n(x)}{n^2}\approx\sum _{n=2}^{\infty } \frac{P_n(x)}{n^2-1}+P_1(x)$. $\endgroup$ – tanghe2014 May 12 '17 at 6:29
  • $\begingroup$ @tanghe2014 Your proposed approximation is an interesting observation. I have aded it to my solution and compared it with the exact values as an EDIT. $\endgroup$ – Dr. Wolfgang Hintze May 12 '17 at 15:47
2
$\begingroup$

The integral

Integrate[Log[2/(1 - q z + Sqrt[1 + q^2 - 2 q z])]/q, {q, 0, 1}]

may be found in the following way : Calculate the derivative of the integrand with respect to z and determine the antiderivative with respect to q. Then find its limits at q -> 1 (easy) as well as at q -> 0 (harder, use Series[_, {q, 0, 0}]) and integrate their difference then again with respect to z to obtain

(ArcTanh[z]^2 - Log[ (1 - z^2)/4]^2/4 - 
2 (PolyLog[2, Sqrt[(1 - z)/2]] - PolyLog[2, -Sqrt[(1 - z)/2]]))/2 + const

A look at the numerical difference at z = 0 of the original integral and the obtained result shows that const is equal to

(-Pi^2 + 4 ArcSinh[1]^2 + 2 Log[2]^2 + 16 PolyLog[2, 1/Sqrt[2]] + 
4 PolyLog[2, 2 (-1 + Sqrt[2])])/8 = 1.644934066 ... = Pi^2/6.
| improve this answer | |
$\endgroup$
1
$\begingroup$

This is not a answer how to find, only a solution. From this site closed form expression is:

$\sum _{n=1}^{\infty } \frac{P_n(x)}{n^2}=\frac{1}{24} \left(4 \pi ^2+12 \tanh ^{-1}(x)^2-3 \log ^2\left(\frac{1}{4} \left(1-x^2\right)\right)-48 \text{Li}_2\left(\frac{\sqrt{1-x}}{\sqrt{2}}\right)+12 \text{Li}_2\left(\frac{1-x}{2}\right)\right)$

f[x_, m_] := Sum[LegendreP[n, x]/n^2, {n, 1, m}] // N
Plot[{f[x, 100], 1/24 (4 \[Pi]^2 + 12 ArcTanh[x]^2 - 3 Log[1/4 (1 - x^2)]^2 - 
 48 PolyLog[2, Sqrt[1 - x]/Sqrt[2]] + 
 12 PolyLog[2, (1 - x)/2])}, {x, -1, 1}, PlotStyle -> {Red, {Dashed, Black}}]

enter image description here

| improve this answer | |
$\endgroup$
  • $\begingroup$ Beautiful! I hope some of these formulas will be integrated into Mathematica at some point, @DanielLichtblau. $\endgroup$ – Roman Nov 15 at 12:38
  • $\begingroup$ @Roman. I would like that too.:) $\endgroup$ – Mariusz Iwaniuk Nov 15 at 12:46
  • $\begingroup$ The expression may further be simplified to Pi^2/6 - (1/2)*Log[(1 - x)/2]*Log[(1 + x)/2] - PolyLog[2, Sqrt[1 - x]/Sqrt[2]] + PolyLog[2, -(Sqrt[1 - x]/Sqrt[2])]. By the way, I am the author of the quoted web site... $\endgroup$ – Andreas Nov 15 at 13:16
  • 1
    $\begingroup$ Awesome work, @Andreas ! $\endgroup$ – Roman Nov 15 at 14:21

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.