0
$\begingroup$

I have a expression:

13 + 6 Sqrt[6 - x] x == x

I want to simplify the Sqrt to be -169+26 x+215 x^2-36 x^3==0.But Simplify[13 + 6 Sqrt[6 - x] x == x, Assumptions -> x < 6] don't work.And I have tried ComplexityFunction:

FullSimplify[13 + 6 Sqrt[6 - x] x == x, 
 ComplexityFunction -> (1000 Count[#, _Sqrt, {0, Infinity}] + 
     LeafCount[#] &)]

I can get anything still.So how to elminate the Sqrt?

$\endgroup$
12
  • 3
    $\begingroup$ I don't understand. How did you obtain the second expression from the first? They don't seem to have the same solutions either. $\endgroup$
    – MarcoB
    Commented Feb 21, 2017 at 14:52
  • $\begingroup$ @MarcoB Confused too.I just want elminate the Sqrt.I get it by ((x-13)/6x)^2+x-6==0//FullSimplify//Expand $\endgroup$
    – yode
    Commented Feb 21, 2017 at 15:06
  • $\begingroup$ OK but that still didn't explain the relationship between the expression with the Sqrt and the equation you have in comments. How did you get from ((x - 13) / 6 x)^2 + x - 6 == 0 to 13 + 6 Sqrt[6 - x] x == x? $\endgroup$
    – MarcoB
    Commented Feb 21, 2017 at 15:08
  • $\begingroup$ @MarcoB Move ` x - 6` to right of the equal sign,then execute sqrt...and so on $\endgroup$
    – yode
    Commented Feb 21, 2017 at 15:12
  • 3
    $\begingroup$ It should be (x-13)/(6x), not (x-13)/6x. $\endgroup$
    – Szabolcs
    Commented Feb 21, 2017 at 15:40

3 Answers 3

4
$\begingroup$

Perhaps:

Solve[13 + 6 Sqrt[6 - x] x == x, x, Cubics -> False]

{{x -> Root[169 - 26 #1 - 215 #1^2 + 36 #1^3 &, 1]}}

$\endgroup$
1
  • $\begingroup$ little wired. :)Thanks all the same. $\endgroup$
    – yode
    Commented Feb 22, 2017 at 2:15
3
$\begingroup$

Adapting the F function from DSolve misses a solution of a differential equation, we get

Clear[rat];
(* rationalize fractional powers *)
rat[eqn_Equal] := rat[Subtract @@ eqn] == 0;
rat[fn_] := Module[{u}, 
   With[{rads = DeleteDuplicates@Cases[fn, Power[a_, b_Rational] :> u[a, b], Infinity]}, 
    First@GroebnerBasis[
      Flatten@{fn /. Power[a_, b_Rational] :> u[a, b], 
        Map[
         Numerator@Together[           (*gets rid of denominators in neg.powers*)
           #^Denominator[Last@#] - First[#]^Numerator[Last@#]
           ] &, 
         rads]}, rads]]];

rat[13 + 6 Sqrt[6 - x] x == x]

(* Out[79]= 169 - 26 x - 215 x^2 + 36 x^3 == 0 *)
$\endgroup$
2
  • $\begingroup$ Little long...;) $\endgroup$
    – yode
    Commented Feb 21, 2017 at 16:15
  • 2
    $\begingroup$ @yode I think you mean "too general." :) $\endgroup$
    – Goofy
    Commented Feb 21, 2017 at 16:19
0
$\begingroup$

GroebnerBasis can do this:

First[GroebnerBasis[13 + 6 Sqrt[6 - x] x - x, x]]

169-26 x-215 x^2+36 x^3

$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.