4
$\begingroup$

I am given the following equation for the position of a particle:

${\bf r}(t) = \sin(11t)\ {\bf i} + t^4\ {\bf j} + \cos (11 t)\ {\bf k}$

I seek to:

  1. Find the equation of the tangent line at $t=0.2$.
  2. Graph the tangent line at $t=0.2$, and the path of the particle from $t=0$ to $t=2 \pi/11$ on the same graph. The line segment for the tangent line should be symmetric about the point of tangency.

I'm having trouble even declaring the vector function. I'm trying r[t_] := {Sin[11 t], t^4, Cos[11 t]}, but I keep getting an error message. SetDelayed::write: Tag List in {0.808496,0.0016,-0.588501}[t_] is Protected. >>So my first question would be, how do you properly define a 3D vector function?

After getting a vector function declared, how would I go about solving for $t=0.2$? Would it be as simple as r[0.2] or would I have to use Evaluate[]? I'm very new to the world of programming, as I'm more on the hardware side of the spectrum. Any help would be greatly appreciated.

$\endgroup$
5
$\begingroup$

Your error message is likely due to the fact that you have a prior definition of r or t or both. Hence clear them:

Clear[r,t];

Then:

myposition[t_] := {Sin[11 t], t^4, Cos[11 t]};
Show[
 ParametricPlot3D[myposition[t], {t, 0, 2 π/11}, BoxRatios -> {1,1,1}],
 Graphics3D[{Red, Thickness[0.01], 
     Arrow[{myposition[.2], myposition[.2] + .03 (D[myposition[t], t] /. t -> 0.2)}]}]]

enter image description here

If the line segment (arrow) needs to be symmetric with respect to the point:

myposition[t_] := {Sin[11 t], t^4, Cos[11 t]};
Show[ParametricPlot3D[myposition[t], {t, 0, 2 \[Pi]/11}, 
  BoxRatios -> {1, 1, 1}], 
 Graphics3D[{Red, Thickness[0.005], 
   Arrow[{myposition[.2] - (k = .03 (D[myposition[t], t] /. 
           t -> 0.2)), myposition[.2] + k}]}]]

Or:

Manipulate[
 Show[ParametricPlot3D[myposition[t], {t, 0, 1}],
      Graphics3D[{Red, PointSize[0.02], Point[myposition[t]]}, 
        PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}],
      Graphics3D[{Red, Thickness[0.01], 
         Arrow[{myposition[t], 
         myposition[t] + .03 (D[myposition[tt], tt] /. tt -> t)}]}]],
 {t, 0, 1}]

The tangent line defined at $t = .2$ is:

myline = myposition[.2] + t (D[myposition[tt], tt] /. tt -> 0.2)

(* {0.808496 - 6.47351 t, 0.0016 + 0.032 t, -0.588501 - 8.89346 t} *)

$\endgroup$
  • $\begingroup$ If you like the question and gave an answer, consider giving the question an upvote. With 1 point of reputation, newcomers can't do much. You need 15 pts even to upvote... $\endgroup$ – halirutan Feb 21 '17 at 1:06

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.