5
$\begingroup$

I would like to do the integral

$$I=\int_0^{2\pi}d\phi\frac{\ln(e^{i\phi}+e^{-i\phi}-\frac{5}{2})}{e^{i\phi}+e^{-i\phi}-\frac{5}{2}}.$$

Numerically, we readily find that it has a specific finite value:

fun = -(5/2) + E^(-I \[Phi]) + E^(I \[Phi]);
NIntegrate[ Log[fun]/fun, {\[Phi], 0, 2 \[Pi]}]

-0.493368 - 13.1595 I

Now, if we want to consider the integral analytically, we could substitute for instance

$$e^{i\phi}=z~~~,~~~d\phi=\frac{-i}{z}dz$$

which leads to

$$I=-i\oint_{|z|=1}\frac{\ln\left[\frac{1}{z}(z - \frac{1}{2}) (z - 2)\right]}{(z - \frac{1}{2}) (z - 2)}$$

This looks like there is a pole at z=1/2 within the unit circle. So I tried to get the residue:

Residue[-(( I Log[((-2 + z) (-(1/2) + z))/z])/((-2 + z) (-(1/2) + z))), {z, 1/2}]

Residue[-(( I Log[((-2 + z) (-(1/2) + z))/z])/((-2 + z) (-(1/2) + z))), {z, 1/2}]

which just gave back the input. Also, the 1/z term inside the logarithm seems to blow up inside the unit circle as well. This integral is confusing and does not seem to be accessible via straightforward analytical methods. Is there a way to evaluate it exactly using Mathematica?

$\endgroup$
  • 1
    $\begingroup$ Feynman's Trick is the way. $\endgroup$ – TeM Feb 16 '17 at 23:30
  • $\begingroup$ That guy got so many, which one are you referring to? Introduce parameter and take derivative, and integrate parameter after? $\endgroup$ – Kagaratsch Feb 16 '17 at 23:40
  • 1
    $\begingroup$ Yes, of course. Consider the function define by $ I(t) := \int_0^{2\pi} \frac{\log\left(t \cos\phi-\frac{5}{2}\right)}{2 \cos\phi - \frac{5}{2}} \text{d}\phi$. $\endgroup$ – TeM Feb 16 '17 at 23:46
  • 1
    $\begingroup$ By expanding the function inside the closed loop integral using Series at z=1/2 doesn't have the term (z-1/2)^-1. $\endgroup$ – Anjan Kumar Feb 16 '17 at 23:49
8
$\begingroup$

Noting that $e^{\text{i}\phi} + e^{-\text{i}\phi} = 2\cos\phi$, simply write:

f[t_] := Log[t Cos[fi] - 5/2]/(2 Cos[fi] - 5/2)

g[t_] := Integrate[f[t], {fi, 0, 2 Pi}]

h[t_] := Integrate[Integrate[f'[t], {fi, 0, 2 Pi}], t]

Clear[c]; {{c}} = {c} /. Solve[g[0] == (h[t] /. t -> 0) + c, c];

Limit[h[t] + c, t -> 2, Direction -> 1] // Expand

I get:

$-\frac{2}{3}\pi\log\left(\frac{81}{64}\right) - \frac{4}{3}\pi^2\,\text{i} \approx -0.493368 - 13.1595\,\text{i}$

without knowing anything about Complex Analysis.


Theorems on the derivation under the integral sign

Let $\Gamma \subseteq \mathbb{C}$ a smooth curve arc and $f : \Gamma \to \mathbb{C}$ is a continuous function. Called $F : \mathbb{C}\backslash \Gamma \to \mathbb{C}$ the function defined by placing $F(\zeta) := \int_{\Gamma} \frac{f(z)}{z-\zeta}\text{d}z $, it is holomorphic in $\mathbb{C}\backslash \Gamma$. In addition, $F$ possesses in $\mathbb{C}\backslash \Gamma$ derivatives of still higher order (which are therefore all holomorphic functions in $\mathbb{C}\backslash \Gamma$) and, for each $n \in \mathbb{N}$, you have $F^{(n)}(\zeta) = n!\int_{\Gamma} \frac{f(z)}{(z-\zeta)^{n+1}}\text{d}z$, i.e. the derivatives of $F$ can be calculated by deriving under the integral sign.

Wanting to simplify things, let $\Omega \subset \mathbb{R}^n$ an open limited, $I \subset \mathbb{R}$ an open interval and $f : I \times \bar{\Omega} \to \mathbb{R}$ a continuous function. If $\frac{\partial f}{\partial t}(t,x)$ continues exists for each $(t,x) \in I \times \bar{\Omega}$, then you have $\frac{\text{d}}{\text{d}t}\int_{\Omega} f(t,x)\text{d}x = \int_{\Omega} \frac{\partial f}{\partial t}(t,x)\text{d}x$.

$\endgroup$
  • $\begingroup$ Wait, so you get a wrong sign in the imaginary part, compared to numerical integration? Wonder why that is... $\endgroup$ – Kagaratsch Feb 17 '17 at 0:18
  • $\begingroup$ You're right, now I corrected. $\endgroup$ – TeM Feb 17 '17 at 0:25
  • $\begingroup$ But you know about the uniform convergence :). Maybe you should explain why it is possible to exchange the order of two operations... $\endgroup$ – yarchik Feb 17 '17 at 0:27
  • $\begingroup$ @yarchik: it is trivial aspects, questionable as the math section. Here I thought it was more appropriate to simply show the code in MMA. Quite simply, for 0<t<2 the function f '(t) is C^1 in its own domain and then you can derive under integral sign. $\endgroup$ – TeM Feb 17 '17 at 0:43
  • 1
    $\begingroup$ @Kagaratsch: The reference theorems are essentially those mentioned above, to be used according to your needs. Note the statements, for the demonstrations that just do a simple search and choose the one you like best. $\endgroup$ – TeM Feb 17 '17 at 13:30
4
$\begingroup$

The whole thing is much simple. Only apply 'ExpToTrig' and you get the right analytical definite integral.

     {int = 
     Integrate[Log[fun]/fun // ExpToTrig,{Phi, 0, 2 Pi}] // 
     FullSimplify, N[int]}

     (*   {-(4/3) I Pi (Pi - I Log[9/8]), -0.493368 - 13.1595 I}   *)
$\endgroup$
1
$\begingroup$

This is probably cheating, but it seems to work.

First we get the anti-derivative

int = -I Integrate[Log[1/z - 5 /2 + z]/(1 - 5 /2 z + z^2), z] /. z -> Exp[I \[Phi]];

It is important to do this in the z variable, since in the $\phi$ Mathematica does not return a result.

Then we evaluate the upper and lower boundaries:

 Assuming[ep>0,Series[(int/.\[Phi]->(2\[Pi]-ep))-(int/.\[Phi]->(ep)),{ep, 0, 0}]//FullSimplify]

enter image description here

Setting ep to zero or some value very close to zero, and checking numerically, we get the correct imaginary part of the result. The real part does not agree though. Still, we can assume that the real part is similar to what comes out, so we consider -4\[Pi] Log[x]/3==-0.49336842604379194 which has the solution x=9/8. In this way we deduce

result = -((4 I \[Pi]^2)/3) - 4/3 \[Pi] Log[9/8];

And confirm

fun = -(5/2) + E^(-I \[Phi]) + E^(I \[Phi]);
nint=NIntegrate[ Log[fun]/fun, {\[Phi], 0, 2 \[Pi]},WorkingPrecision->300];
nint-result 

0.*10^-300 + 0.*10^-300 I

That was not entirely analytic though. I'll try Feynman trick next.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.