1
$\begingroup$

I would like to draw the solution of the following equation in a log-log plot of $\lambda$ against $M$.

$$10^{-10} = \frac{\lambda^{2}}{(4\pi)^{2}}\int_{0}^{1}dz\frac{(1-x)^{3}}{(1-x)^{2}+zM^{2}}$$

Here is my code:

table = Table[{Exp[M], λ /. 
     NSolve[((λ^2)/(4 *Pi)^(2)) * 
         NIntegrate[(((1-x)^3)/((1-x)^2 + Exp[2 M] x)), {x, 0, 1}] == 
                                    10^(-10), λ][[2]]}, 
     {M, -15, 15, 0.03}];
 ListLogLogPlot[table, Joined \[RightArrow] True, 
 AxesOrigin \[RightArrow] {1, 1}]

With this code, I get a list of error messages and a list of the output values, but not the plot. How do I get the plot?

$\endgroup$
  • $\begingroup$ Your question is unclear. Do you want the value of the full expression for different values of λ and $M$? And what is AxesoutpOrigin? And why use \[Minus] instead of -? $\endgroup$ – David G. Stork Feb 10 '17 at 1:46
  • $\begingroup$ Oh, no! See my edits in the equation and in the code. $\endgroup$ – nightmarish Feb 10 '17 at 1:50
  • $\begingroup$ I want the solution of the edited equation. AxesoutpOrigin should actually be AxesOutput. And I've replaced [Minus] with the minus sign. $\endgroup$ – nightmarish Feb 10 '17 at 1:52
  • $\begingroup$ A \[Minus] remains... $\endgroup$ – David G. Stork Feb 10 '17 at 1:53
  • $\begingroup$ all of them now replaced $\endgroup$ – nightmarish Feb 10 '17 at 1:53
2
$\begingroup$

Why not make things easier and solve the integral exactly?

After making the integration variable consistently $\text{x}$ and changing it to $\text{x}\to 1-\text{x}$, the integral can be calculated explicitly. (In order to assist Mathematica in solving the integral we also assume temporarily that $\text{M}<-2$ such that the roots of the denominator are real.)

We get

f[M_] = Integrate[x^3/(x^2 + (1 - x) M^2), {x, 0, 1}, Assumptions -> M < -2] //
   FullSimplify

(* Out[111]= (Sqrt[-4 + M^2] (1 + 2 M^2) - M^2 Sqrt[-4 + M^2] (-1 + M^2) Log[M^2] - 
 M^3 (-3 + M^2) Log[1/2 (-2 + M^2 - M Sqrt[-4 + M^2])])/(2 Sqrt[-4 + M^2]) *)

$$f(\text{M})=\int_0^1 \frac{x^3}{x^2+(1-x)M^2 } \, dx\\= \frac{1}{2} \left(\left(2 M^2+1\right)-M^2 \left(M^2-1\right) \log \left(M^2\right)\right)\\-\frac{\left(M^3 \left(M^2-3\right)\right) \log \left(\frac{1}{2} \left(M^2- M\sqrt{M^2-4}-2\right)\right)}{2 \sqrt{M^2-4}}$$

The result now holds for all real $\text{M}$.

At the special points it is

Limit [f[M], M -> 0]

(* Out[113]= 1/2 *)

{Limit [f[M], M -> 2], Limit [f[M], M -> -2]}

(* Out[115]= {17/2 - 12 Log[2], 17/2 - 6 Log[4]} *)

Series[f[M], {M, \[Infinity], 2}] // Normal

(* Out[148]= (-(11/6) - 2 Log[1/M])/M^2 *)

And here's the graph

Plot[f[M], {M, -10, 10}, 
 PlotLabel -> "The integral as a function of M"]

enter image description here

Now the function $\lambda $ is defined as

ld[M_] := 4 \[Pi] 10^-5/Sqrt[f[M]]

A log-log-plot (which is naturally confined to positive quantities) is then

LogLogPlot[ld[M], {M, .001, 15}, PlotLabel -> "Log-log-plot", 
 AxesLabel -> {"Log[M]", "log[\[Lambda]]"}]

enter image description here

$\endgroup$
  • $\begingroup$ +1 Evaluating the integral is a great enhancement. $\endgroup$ – Jack LaVigne Feb 10 '17 at 14:26
1
$\begingroup$

Here is your graph, once you delete the non-converged values:

ListLogLogPlot[table, AxesOrigin -> {1,1}]

enter image description here

$\endgroup$
  • $\begingroup$ How can I make (1,1) the point where the axes cross? $\endgroup$ – nightmarish Feb 10 '17 at 2:01

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.