2
$\begingroup$

I am trying to verify my manual solution for this problem by any way, so I tried NDSolve, and DSolve, with no success. Can some one help, or even give me the final numbers :D I need the first 3 alphas for a bucklingenter image description here

Here is my interpretation (yields the NDSolve::ivone error)

xDim = 1;
yDim = 1/2;

alpha = 4 Pi^2;

eqn2D = D[w[x, y], {x, 4}] + 2 D[w[x, y], {x, 2}, {y, 2}] + 
   D[w[x, y], {y, 4}] + alpha D[w[x, y], {x, 2}];

buck2D = NDSolve[{eqn2D == 0,
   w[-xDim, y] == 0,
   w[xDim, y] == 0,
   w[x, -yDim] == 0,
   w[x, yDim] == 0,
   Derivative[2, 0][w][-xDim, y] == 0,
   Derivative[2, 0][w][xDim, y] == 0,
   Derivative[0, 2][w][x, -yDim] == 0,
   Derivative[0, 2][w][x, yDim] == 0},
   w, {x, -xDim, xDim}, {y, -yDim, yDim}, Method -> {"MethodOfLines"}]

Even the 1D solution seems incorrect:

youngs = 2*^5;(*N/mm^2, steel*)

sideLength = 1.78;(*mm*)
areaMomInertia = sideLength^4/12;(*mm^2, square section*)

load = 42;(*N*)

alpha = load/(youngs areaMomInertia);

eqn1D = D[w[x], {x, 4}] + alpha D[w[x], {x, 2}];

buck1D = NDSolveValue[{eqn1D == 0,
   w[0] == 0,
   w[200] == 0,
   (D[w[x], {x, 1}] /. x -> 0) == 0,
   (D[w[x], {x, 1}] /. x -> 200) == 0},
  w, {x, 0, 200}]

Plot[buck1D[x], {x, 0, 200}, PlotRange -> All]

References:

https://uta-ir.tdl.org/uta-ir/bitstream/handle/10106/300/umi-uta-1041.pdf http://www.arpnjournals.com/jeas/research_papers/rp_2007/jeas_0207_35.pdf

$\endgroup$
  • 1
    $\begingroup$ Can you include your NDSolve code attempt? $\endgroup$ – Young Feb 7 '17 at 4:37
  • $\begingroup$ NDSolve[{eqn==0,w[-1,y]==0,w[1,y]==0,w[x,-(1/2)]==0,w[x,1/2]==0,(w^(0,2))[x,-(1/2)]==0,(w^(0,2))[x,1/2]==0,(w^(2,0))[1,y]==0,(w^(2,0))[-1,y]==0},w,{x,-1,1},{y,-(1/2),1/2}] $\endgroup$ – Aladdin Feb 7 '17 at 4:46
  • $\begingroup$ Gives me the error Boundary values may only be specified for one independent variable. \ Initial values may only be specified at one value of the other \ independent variable. $\endgroup$ – Aladdin Feb 7 '17 at 4:46
  • 3
    $\begingroup$ (w^(0,2))[x,-(1/‌​2)]==0 should be more like this Derivative[0, 2][w][x, -1/2] == 0 ... and I was unclear ... please share enough code so we can run your NDSolve attempt $\endgroup$ – Young Feb 7 '17 at 4:53
  • 2
    $\begingroup$ No, (w^(0,2)) is meaningless, it just looks correct, the StandardForm of Derivative can't be typed in this way, check this post for more details. Then, if this is an eigenvalue problem, I think your problem is similar to this one. $\endgroup$ – xzczd Feb 9 '17 at 2:40
1
$\begingroup$

Since you just want to verify your manual solution by any way, let me show you a solution based on finiteFourierSinTransform.

dim@x = 1;
dim@y = 1/2;

Clear[alpha]

With[{w = w[x, y]}, 

 eqn = D[w, {x, 4}] + 2 D[w, {x, 2}, {y, 2}] + D[w, {y, 4}] + alpha D[w, {x, 2}] == 0;

 help = ({w == 0, D[w, {#, 2}] == 0} /. List /@ {# -> -dim@#, # -> dim@#} // Flatten) &;

 {bc@x, bc@y} = help /@ {x, y}]

Then make finite Fourier sine transform with respect to $x$, and substitute bc@x in:

Format@finiteFourierSinTransform[f_, __] := Subscript[\[ScriptCapitalF], s][f]

ffst = finiteFourierSinTransform;
{teq, tbc@y} = ffst[{eqn, bc@y}, {x, -dim@x, dim@x}, n] /. (Rule @@@ bc@x /. y -> y_)

Once again, make finite Fourier sine transform. This time we eliminate derivatives with respect to $y$:

tteq = ffst[teq, {y, -dim@y, dim@y}, m] /. 
     ffst[ffst[a_, b__], c__] :> ffst[ffst[a, c], b] /. (Rule @@@ tbc@y /. 
      x -> x_) /. (Rule @@@ bc@x /. y -> y_) // Simplify

Mathematica graphics

At this point, it's clear that $w$ only has a trivial solution, unless the coefficient (-4 alpha n^2 + (4 m^2 + n^2)^2 Pi^2) equals zero, which is relevant to buckling. It's clear that m and n won't be that large for first 3 alphas, so let's find them by brute force:

alphavalue = Solve[tteq[[1, 1]] == 0, alpha][[1, 1, -1]]
Sort@Union@Flatten[Table[{alphavalue, {n, m}}, {m, 5}, {n, 5}], 1][[1 ;; 3]]
(* {{4 π^2, {2, 1}}, {(169 π^2)/36, {3, 1}}, {(25 π^2)/4, {1, 1}}} *)

The first one is 4 π^2, which is exactly the value tested in your question.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.