Print expressions using local variables in Module without Dollar sign: is that possible

Question

In a Module, I want to print the result of some data fit. I use something like this:

PlotDD[r_, n_, R_] :=
 Module[{d, fit, ft, pl, x}
       ,ft = Table[{d, PythAbst[5, r, n, d, R]}, {d, 0., 10, .1}];
        d =.;
        fit = ToString[Fit[ft, {1, d, d^2}, d]];
        Print["ft[d]=", fit];
        ...
       ];

The output of the print statement is:

ft[d]=                                                   2
0.000402667 + 0.11131 d$28040 + 0.000883443 d$28040

where the 2 in the first line is the exponent of d$28040.

I know, appending a Dollar sign plus some unique number is how local variables of Module are made. But I want it printed without this $-number, I would like it as

ft[d]=0.000402667 + 0.11131 d$ + 0.000883443 d^2

I avoid the exponent in an extra line applying InputForm first. I tried to enclose things in N[#,6] to limit digits to something physically meaningful but the latter does not work for me. Any idea about this?

Answer 1

The basic issue is the use of ToString and InputForm. There is no need for them, since Print works with expressions as well as strings. Here is a function that takes some data, and prints the quadratic fit, using my earlier suggestion in the comments:

PlotDD[data_] := Module[{d, fit},
    d /: MakeBoxes[d, StandardForm] = "d";
    fit = Fit[data, {1, d, d^2}, d];
    Print["ft[d]=", fit]
]

An example from the documentation of Fit

PlotDD[{{0,1},{1,0},{3,2},{5,4}}]

ft[d]=0.678392 -0.266332 d+0.190955 d^2

Answer 2

I use the following function

str[expr_]:=Module[{},StringReplace[ToString[expr,
   FormatType->TraditionalForm],c:LetterCharacter~~"$"~~DigitCharacter..:>c]];

To use, just wrap the content you want the $ removed from by this function. Example usage using Carl example below.

PlotDD[data_]:=Module[{d,fit},
  fit=Fit[data,{1,d,d^2},d];
  Print["ft[d]=",str@fit]]
PlotDD[{{0,1},{1,0},{3,2},{5,4}}]

I did not write the above function. It was written by answer to my question on this many years ago by Hannes Kessler in this post at now closed group comp.soft-sys.math.mathematica and I've used it since and it works well.