Adding space between rows in ArrayPlot

Question

Is it possible to add space between rows and/or columns in ArrayPlot?

From this

 ArrayPlot[Table[x*y, {x, 4}, {y, 20}], Mesh -> True, ImageSize -> 1 -> 25]

i would like to get something like this

I tried the following code but obviously it is not work as desired

  (ArrayPlot[{#}, Mesh -> True, ImageSize -> 1 -> 25]) & /@ Table[x*y, {x, 4}, {y, 20}] // TableForm

Answer 1

ArrayPlot may not be the best tool for this kind of thing. Here is a way using GraphicsGrid that allows quite flexible control over the appearance.

tab = Table[x*y, {x, 4}, {y, 20}]; 
GraphicsGrid[Table[g = (Max[tab] - tab[[i, j]])/Max[tab];
    Graphics[{RGBColor[g, g, g], EdgeForm[Directive[Black]], Rectangle[]}],
        {i, 1, 4}, {j, 1, 20}], Spacings -> {20, 200}, ImageSize -> 600]

You can control the overall size with ImageSize. Control the vertical and horizontal spaces with the two Spacings parameters. Control the color with the RGBColor parameter. The EdgeForm directives control the appearance of the edges.

Answer 2

ArrayPlot[Table[x y, {x, 4}, {y, 20}], 
  Mesh -> True,
  ImageSize -> 1 -> 25,
  MeshStyle -> {{White, Thickness[0.02]}, {White, Thickness[0.02]}}]

Answer 3

table = Table[x*y, {x, 4}, {y, 20}];    

Using ArrayPlot with PlotRange -> {0, Max[table]}:

ArrayPlot >> Details and Options:

With the default setting for ColorFunction, PlotRange->{$a_{min}$, $a_{max}$} specifies that values from $a_{min}$ to $a_{max}$ should be shown with gray scales varying from white to black.

Column[ArrayPlot[{#}, Mesh -> All, ImageSize -> 1 -> 40, PlotRange -> {0, Max[table]}, 
 PlotRangePadding -> .1, ImagePadding -> .1] & /@ table, Spacings -> .5]

Using ListDensityPlot:

data = 1 - table/Max[table]; 

Column[ListDensityPlot[{#, #}, InterpolationOrder -> {0, 0}, 
  ColorFunctionScaling -> False, ColorFunction -> GrayLevel, 
  AspectRatio -> 1/20, Mesh -> All, 
  MeshStyle -> Directive[Antialiasing -> False, GrayLevel[-1 + GoldenRatio]], 
  Frame -> False, ImageSize -> 1 -> 40] & /@ data, Spacings -> 1]

Answer 4

The following approach relies on ArrayPlot to generate an appropriately colored and scaled Raster object. I then extract the data and specifications from this object (size, scale), and split the data up into rows, each one of which is used to generate a new Raster object with the specifications obtained above, but appropriately resized. The objects obtained, i.e. the "rows" of the original ArrayPlot are then re-combined using Column to introduce spacing. The process is wrapped in a custom function called spacedArray:

Clear[spacedArray]
spacedArray[data_?MatrixQ] := Block[
  {values, rectangle, range},
  {values, rectangle, range} = First@Cases[
     ArrayPlot[data, Mesh -> True],
     Raster[values_, rectangle_, range_] :> {values, rectangle, range},
     Infinity
   ];
  rectangle[[2, 2]] = rectangle[[2, 2]]/First@Dimensions[values];
  Column[
   Graphics[Raster[{#}, rectangle, range], ImageSize -> 1 -> 25] & /@ values
  ]
]

Here is the result on the original toy data:

spacedArray[Table[x*y, {x, 4}, {y, 20}]]

... and on a different data set:

spacedArray[Table[x*y, {x, 5}, {y, 10}]]

Notice that in the latter case the size of the cells is retained, although the overall size and aspect ratio of the plot changes substantially.

Vertical spacing can be controlled with appropriate options to Column. Obviously, this solution is still missing the mesh lines: those could be extracted from ArrayPlot as well as Line objects (two sets of lines, for the horizontal and vertical mesh respectively), but that seems tedious. Perhaps direct construction from Graphics primitives would be best at that point.