1
$\begingroup$

I'm given the region bounded by $x=0$ and $x=4y^2-y^3$.

Show[
 ContourPlot[{x == 4 y^2 - y^3, x == 0}, {x, -1, 10}, {y, 0, 4}],
 RegionPlot[0 <= x <= 4 y^2 - y^3, {x, 0, 256/27}, {y, 0, 4}],
 Axes -> True
 ]

enter image description here

I'm asked to rotate it about the x-axis.

Show[
 RevolutionPlot3D[{4 y^2 - y^3, y, 0}, {y, 0, 4}, 
  RevolutionAxis -> {1, 0, 0}, AxesLabel -> {"x", "y"}],
 RevolutionPlot3D[{0, y, 0}, {y, 0, 4}, RevolutionAxis -> {1, 0, 0}],
 BaseStyle -> Opacity[0.4]
 ]

enter image description here

Now, this is similar to a question I posted at Area of surface of revolution. I've found the volume using the cylindrical shell method.

Integrate[2 \[Pi] y (4 y^2 - y^3), {y, 0, 4}]

The answer is $512\pi/5$. I'd like to use Mathematica's Volume command to find the volume, but I've been unsuccessful. Tough problem. Does anyone have a suggestion?

Update: This can help show that it is a rotation about the x-axis.

Manipulate[
 ParametricPlot3D[{4 y^2 - y^3, y Cos[t], y Sin[t]}, {y, 0, 4}, {t, 0,
    tau}, AxesLabel -> {"x", "y"}, PerformanceGoal -> "Quality", 
  PlotStyle -> Opacity[0.8], PlotRange -> {{0, 10}, {-4, 4}, {-4, 4}}],
 {{tau, 0.1}, 0, 2 \[Pi]}]
$\endgroup$
  • $\begingroup$ @C.E. Yes it is. The option RevolutionAxis -> {1, 0, 0}] causes the revolution across the x-axis. I've also updated my original post, adding some axes labels and a manipulate activity to show the rotation. $\endgroup$ – David Jan 31 '17 at 18:26
  • $\begingroup$ My bad, I misread the plot. $\endgroup$ – C. E. Jan 31 '17 at 18:31
5
$\begingroup$
ir = ImplicitRegion[
  x^2 + y^2 < 16 && 
   0 < z < 4 (x^2 + y^2) - (x^2 + y^2)^(3/2), {{x, -4, 4}, {y, -4, 
    4}, {z, 0, 10}}]
Volume[ir]

yields: $512\pi/5$

$\endgroup$
  • $\begingroup$ This was really helpful. I showed this to my colleague instructor and we figured it out. Thanks for posting this. $\endgroup$ – David Feb 1 '17 at 17:00
  • $\begingroup$ We understood your shift as thinking about rotating the image around the z-axis. I tried to adjust your code so that it rotated around the x-axis. I tried: ir = ImplicitRegion[ y^2 + z^2 < 16 && 0 < x < 4 (y^2 + z^2) - (y^2 + z^2)^(3/2), {{x, 0, 10}, {y, -4, 4}, {z, -4, 4}}] then Volume[ir], but it did not work, giving me a very quick answer "unable to compute the volume of the region." Is it a rule that ImplicitRegion will only work if I adjust to rotating about the z-axis, or have I made some other mistake? $\endgroup$ – David Feb 1 '17 at 17:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.