I would like to gather elements of a list separated by a delimiter ":"
lis = {"az", "2","b",":","7","b",":","7","c"}
to make:
lis2 = {{az, 2,b},{7,b},{7,c}}
Thanks in advance for any direction...
$\begingroup$
$\endgroup$
2
-
$\begingroup$ Much more elegant than my solution, thank you! $\endgroup$– Suite401Jan 28, 2017 at 6:57
-
$\begingroup$ at least closely related: Partition on sublists beginning with a certain marker elements $\endgroup$– Kuba ♦Jan 28, 2017 at 11:08
Add a comment
|
3 Answers
$\begingroup$
$\endgroup$
2
This
is = {"az", "2", "b", ":", "7", "b", ":", "7", "c"};
DeleteCases[SplitBy[lis, # == ":" &], {":"}]
returns {{"az", "2", "b"}, {"7", "b"}, {"7", "c"}}
-
2$\begingroup$
SameQ[](===) is more suitable here thanEqual[]. $\endgroup$ Jan 28, 2017 at 7:01 -
$\begingroup$
DeleteCases[SplitBy[lis, # === ":" &], {":"..}]would be better since this will also work if multiple separators occur in sequence. $\endgroup$ Nov 23, 2022 at 15:39
$\begingroup$
$\endgroup$
In 10th and later versions you can also use SequenceCases:
SequenceCases[lis, {a : Except[":"] ..} :> {a}]
{{"az", "2", "b"}, {"7", "b"}, {"7", "c"}}
Also:
Split[#, # =!= ":" &] /. ":" | {":"} -> (## &[]) & @ lis
{{"az", "2", "b"}, {"7", "b"}, {"7", "c"}}
$\begingroup$
$\endgroup$
For the benefit of page visitors, this functionality was made available in 2018 through SequenceSplit.
lis = {"az", "2", "b", ":", "7", "b", ":", "7", "c"};
SequenceSplit[lis, {":"}]
{{"az", "2", "b"}, {"7", "b"}, {"7", "c"}}
