1
$\begingroup$

I have to solve the following implicit equation:

1/Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 
   4 y^2 x^2] (Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2] - 
    Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2]
      Cos[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] Cos[
      1/2 Sqrt[4 π^2 + y^2 + 2 y x]] + (4 π^2 + y^2 - 
       2 x^2) Sin[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] Sin[
      1/2 Sqrt[4 π^2 + y^2 + 2 y x]])==0

I am trying :

f[x_, y_] := 
 1/Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 
    4 y^2 x^2] (Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2] - 
     Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2]
       Cos[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] Cos[
       1/2 Sqrt[4 π^2 + y^2 + 2 y x]] + (4 π^2 + y^2 - 
        2 x^2) Sin[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] Sin[
       1/2 Sqrt[4 π^2 + y^2 + 2 y x]])
g[x_, y_] := 
 Assuming[{{x, y} ∈ Reals, x >= 2 π}, Simplify[f[x, y]]]
Solve[g[x, y] == 0, {y}]

I receive the message: Solve: This system cannot be solved with the methods available to Solve.

What's wrong? Any suggestion is much appreciated. Thanks for your help.

$\endgroup$
  • $\begingroup$ Unfortunately, as the docs state, "Solve deals primarily with linear and polynomial equations". As written, your equation may simply be more than Solve can handle. If you can work with a numerical solution, then look into FindRoot. $\endgroup$ – MarcoB Jan 25 '17 at 0:09
  • $\begingroup$ Also, are you sure that you want to solve only for $y$? Any solution would be expressed as a function of $x$ then. Are you trying to find an explicit expression for $y=f(x)$? There may not be one. $\endgroup$ – MarcoB Jan 25 '17 at 0:17
  • $\begingroup$ There seems to be an extra conditional == in f[x,y]. $\endgroup$ – Anjan Kumar Jan 25 '17 at 0:20
  • $\begingroup$ yes i want an explicit expression for y=f(x), is there a solution? $\endgroup$ – Kimou Jan 25 '17 at 1:10
  • 1
    $\begingroup$ It seems highly unlikely that such a complicated expression has an analytic solution. $\endgroup$ – Felix Jan 25 '17 at 4:08
6
$\begingroup$

A little bit of thought + Mathematica reveals a few symmetric solutions:

eqn =(*1/Sqrt[16 π^4+8 π^2 y^2+y^4-4 y^2 x^2] *)
  (Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2] - 
     Sqrt[16 π^4 + 8 π^2 y^2 + y^4 - 4 y^2 x^2] Cos[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] *
        Cos[1/2 Sqrt[4 π^2 + y^2 + 2 y x]] +
   (4 π^2 + y^2 - 2 x^2) Sin[1/2 Sqrt[4 π^2 + y^2 - 2 y x]] *
        Sin[1/2 Sqrt[4 π^2 + y^2 + 2 y x]]) == 0;

DeleteDuplicates@Cases[eqn, Sqrt[_], Infinity];
sub = Thread[% -> {u v, u, v}];

Subtract @@ eqn /. sub // Simplify
(*  u v - u v Cos[u/2] Cos[v/2] + (4 π^2 - 2 x^2 + y^2) Sin[u/2] Sin[v/2]  *)

sub2 = {u/2 + v/2 -> P, u/2 - v/2 -> Q, u v -> P^2 - Q^2,
   y^2 -> P^2 + Q^2 - 4 Pi^2, y^2 + 4 Pi^2 -> P^2 + Q^2,
   x^2 -> (P Q)^2/(P^2 + Q^2 - 4 Pi^2)};

(* the form of the u,v equation above can be simplified thus, to show symmetry *)
A - A Cos[b] Cos[c] + B Sin[b] Sin[c] // TrigReduce // 
 Collect[#, {Cos[b - c], Cos[b + c]}] &
% /. {A -> u v, B -> (4 π^2 - 2 x^2 + y^2), b -> u/2, c -> v/2} //. sub2
(*
  A + 1/2 (-A + B) Cos[b - c] + 1/2 (-A - B) Cos[b + c]

  P^2 - Q^2 + 
   1/2 (-2 P^2 + (2 P^2 Q^2)/(P^2 - 4 π^2 + Q^2)) Cos[P] + 
   1/2 (2 Q^2 - (2 P^2 Q^2)/(P^2 - 4 π^2 + Q^2)) Cos[Q]
*)

This last result represents an equation symmetric with respect to P ↔ Q, P ↔ -P and Q ↔ -Q. One can also see that y == 0 is a solution by inspection. This leads to the following:

(* P^2 == Q^2 by even symmetry of preceding result *)
eqnPQ = P^2 == Q^2 /. Reverse /@ sub2 /. Reverse /@ sub;
sol1 = Append[Solve[eqnPQ, y], {y -> 0}]
eqn /. % // Simplify
(* 5 solutions:
   {{y -> -x - Sqrt[-4 π^2 + x^2]}, {y ->  x - Sqrt[-4 π^2 + x^2]},
    {y -> -x + Sqrt[-4 π^2 + x^2]}, {y -> x + Sqrt[-4 π^2 + x^2]},
    {y -> 0}}
   {True, True, True, True, True}    <-- verification
*)

Plot[y /. sol1 // Evaluate, {x, -6 Pi, 6 Pi}, PlotRange -> 6 Pi, 
 AspectRatio -> Automatic]

Mathematica graphics

The red wedges below suggest there are more solutions. The white regions are where the square roots are imaginary.

ContourPlot[
 Subtract @@ eqn // Evaluate,
 {x, -6 Pi, 6 Pi}, {y, -6 Pi, 6 Pi},
 Contours -> {-100, 0, 100, 400},
 ContourShading -> {Black, Red, Blue, Lighter[Blue, 0.33], Lighter[Blue, 0.67]},
 MaxRecursion -> 3]

Mathematica graphics

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.