0
$\begingroup$

I just finished studying and solving problems for plotting but couldn't figure out this one.

The function $f(x) = x^3+Power[x, (3)^-1]$ for the function itself and it's first three derivatives,plot the graph as shown in the picture according to user given start and finish values.

enter image description here

Note:Arguements for plot; PlotTheme->"Scientific",PlotLabel->"Graph of the function f(x)=x3+x1/3"]

I tried Plot[Evaluate[f[x],{x,1,4}], {x, start, stop}, PlotTheme -> "Scientific", PlotLabel -> "f(x)=x3+x1/3 Functions Graph"] ,giving user entered values as 0 and 10.

$\endgroup$
  • $\begingroup$ Alright I made it! Plot[{f[x], f'[x], f''[x], D[f[x], {x, 3}]}, {x, basla, bit}, PlotTheme -> "Scientific", PlotLabel -> "f(x)=x3+x1/3 Fonksiyonunun Grafiği"] but it's still giving a lot of errors lol. $\endgroup$ – Harvey Jan 23 '17 at 20:25
  • 1
    $\begingroup$ You could use f'''[x] for the third derivative. $\endgroup$ – J. M.'s technical difficulties Jan 23 '17 at 21:06
3
$\begingroup$

Try the following:

Clear[f]
f[x_] := x^3 + x^(1/3)

Plot[
  Evaluate@Table[D[f[x], {x, i}], {i, 0, 3}], {x, 1, 10},
  PlotLegends -> "Expressions", PlotTheme -> "Scientific",
  PlotLabel -> "f(x)=x^3+ x^(1/3) function and derivatives\n"
]

Mathematica graphics

The main difference in my opinion is the use of Evaluate in the Plot expression, which forces symbolic evaluation of the derivatives and generation of a simple table of functions. This is necessary because of the Hold attributes of the plotting functions.

The function and derivative list are also generated automatically using a Table expression, which keeps the code tidier, at least in my view.

| improve this answer | |
$\endgroup$
0
$\begingroup$

This is a slight variation on @MarcoB's answer using Tooltip

f[x_] = x^3 + x^(1/3);

Plot[
 Evaluate[Tooltip /@
   {f[x], f'[x], f''[x], f'''[x]}],
 {x, 0, 10},
 Frame -> True,
 Axes -> False,
 PlotRange -> {-40, 620},
 PlotLabel -> ToString[
    HoldForm[f[x]] == f[x], TraditionalForm] <>
   " Fonksiyonunun Grafiği",
 PlotLegends -> {"f(x)", "f'(x)", "f''(x)", "f'''(x)"}]

enter image description here

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.