Working with tables of equations in different units

Question

I frequently work with tables of engineering equations in different units. I suppose physicists might do the same thing. For example, a table might look like this:

Some of the values are inputs and others are computed from the inputs. I put them in spreadsheets with each column representing a different set of units, as you can see. In some cases I copy a formula from one column to the other. Other times, I will convert the value in one column to the other column using a unit conversion.

How can I do something like this in Mathematica? Ideally I would like the input values to be easily editable.

The Dream

What would be really cool is if any of the values could be edited and the other values would compute correctly. When I use a spreadsheet, this is impossible. I either have to make the cell contain a number (an independent value), or a formula (a dependent value). Usually, I color the inputs blue. If I could make it so that any cell could be edited and all the others would solve and update correctly, that would be very cool.

Answer 1

I think you want something like this. I use InputField expressions with Dynamic values, and the second parameter of Dynamic to update Symbols.

tF = tC = -40;

TableForm[{InputField[Dynamic[tC, (tC = #; tF = 9/5 # + 32) &]], 
  InputField[Dynamic[tF, (tF = #; tC = 5/9 (# - 32)) &]]}, 
 TableHeadings -> {{"Celsius", "Fahrenheit"}}]

---

Metaprogramming

From your comment below I take it that this behavior is what you want, but you seek an easy way to extend this to larger tables. Here is one approach to that. My function (toFields) takes a List of related equations, each with a single Symbol on the left-hand side which will become the field variable. These Symbols must be unassigned (cleared) at that time. The output is a list of InputFields as shown above, which may then be used in a Row, Grid, TableForm, etc. as desired.

Basic example

Clear[tC, tF, tK]

toFields[
  {tC == 5/9 (tF - 32), tF == 9/5 tC + 32, tK == tC + 273 + 3/20}
] // Column

A complete table

Clear[tC, tF, tK, ft, in, cm]

eq = {
   {tC == 5/9 (tF - 32), tF == 9/5 tC + 32, tK == tC + 273 + 3/20},
   {ft == in/12, in == cm 50/127, cm == 127/50 in}
   };

labels = {{"Celsius", "Fahrenheit", "Kelvin"},
          {"foot", "inch", "centimeter"}};

Grid[
  MapThread[Riffle, {toFields[FieldSize -> 5] /@ eq, labels}]
  , Alignment -> Left
]

Function code

toDynamic[s_][expr : _Equal | _And] := 
  Dynamic[s, (s = #; expr) & /. {Equal -> Set, And -> CompoundExpression}]

toFields[opts : OptionsPattern[InputField]][rel_] := toFields[rel, opts]

toFields[rel : {(_Symbol == _) ..}, opts___] := 
  With[{var = rel[[All, 1]]}, 
    InputField[#, opts] & @ toDynamic[#]@Reduce[rel, DeleteCases[var, #]] & /@ var
  ]