3
$\begingroup$

Donald E. Knuth gives in his paper Convolution Polynomials the code

F[n_, x_] := Sum[f[n, j] x^j, {j, 0, n}]/n!
conv[n_] := LogicalExpand[Series[F[n, x + y], {x, 0, n}, {y, 0, n}]
== Series[Sum[F[k, x] F[n - k, y], {k, 0, n}], {x, 0, n}, {y, 0, n}]]
Solve[Table[conv[n], {n, 0, 4}], [Flatten[Table[f[i, j], {i, 0, 4},{j, 0, 4}]]]]

and then writes: "Mathematica replies that the $F$'s are either identically zero or the coefficients of $F_n(x)$ satisfy ..." How can I get the table following this statement?

$\endgroup$
  • 1
    $\begingroup$ Try fixing the syntax (typo): There a [ in front of Flatten and an extra ] at the end that should be removed. $\endgroup$ – Michael E2 Jan 6 '17 at 11:33
5
$\begingroup$

As Michael notes, deleting the stray brackets will make it work. A better method, however, would be to use SolveAlways[]:

F[n_, x_] := Sum[f[n, j]x^j, {j, 0, n}]/n!
SolveAlways[Table[Series[F[n, x + y], {x, 0, n}, {y, 0, n}] ==
                  Series[Sum[F[k, x]F[n - k, y], {k, 0, n}], {x, 0, n}, {y, 0, n}],
                  {n, 0, 4}], {x, y}][[1]]
   {f[4, 4] -> f[1, 1]^4, f[4, 0] -> 0, f[4, 2] -> 3 f[2, 1]^2 + 4 f[1, 1] f[3, 1],
    f[4, 3] -> 6 f[1, 1]^2 f[2, 1], f[3, 3] -> f[1, 1]^3, f[3, 0] -> 0,
    f[3, 2] -> 3 f[1, 1] f[2, 1], f[2, 2] -> f[1, 1]^2, f[2, 0] -> 0, f[0, 0] -> 1,
    f[1, 0] -> 0}
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.