# Converting a quintic to Bring-Jerrard form

Bring Jerrard Quintic form is a way to transform a general quintic to the form: $x^5+x+d=0$

A method to do this is laid out in this Math.SE post, however, it is pretty tedious. I believe it could be handled better if done by a computer.

I'm not even sure where to start with this one. I have tried many attempts at transforming the math to Mathematica, but all of them have failed. How can I put the quintic in Bring-Jerrard form?

• You've seen this, no? Commented Dec 27, 2016 at 15:03

Coding the linked post seemed relatively straightforward. I do not believe one can do it for a fully general solution, though (too much time & memory, proabably):

Block[{a = 1, b = 2, c = -2, d = 0, e = 1},
res1 = Resultant[poly = x^5 + a x^4 + b x^3 + c x^2 + d x + e,
y - (x^2 + m x + n), x]
];
elim1 = Solve[Thread[CoefficientList[res1, y][[4 ;; 5]] == 0], {m, n}];

(* principal form *)
princ = res1 /. Last@elim1 // Simplify;
Collect[princ, y]
(*
1/64 (131631 + 59105 Sqrt[5]) + 1/64 (80330 + 35434 Sqrt[5]) y -
3/4 (291 + 125 Sqrt[5]) y^2 + y^5
*)

(* Bring-Jerrard transformation *)
res2 = Resultant[princ, z - (y^4 + p y^3 + q y^2 + r y + s), y];
elim2 = Solve[
CoefficientList[res2, z][[4 ;; 5]] == 0],
{5 , 4 p, 3 q}.CoefficientList[princ, y][[1 ;; 3]] == 0},
{p, q, s}];
elim3 = Solve[CoefficientList[res2, z][[3]] == 0 /. Simplify@Last@elim2, r];
sol = Flatten@{Last@elim2, Simplify@First@elim3};

(* takes a long time to simplify *)
bjform = res2 /. sol //
Collect[#, z, Simplify[#, TimeConstraint -> 1] &] &; // AbsoluteTiming
(*
<time constraint warnings omitted
{94.3734, Null}
*)

bjform // N[#, 50] & // Chop[#, 10^-20] &
(*
-5.7647253740168246456506440299463549834109356680148*10^16 -
2.0159908782363565552758349179194608052948233385778*10^13 z + z^5
*)


It seems to work, which I was interested to find out. (The numerical coefficients seem hard to evaluate.)