1
$\begingroup$

I have the following function

(1/(35 \[Pi]^3 (-1 + 
t^2)^13))65536 t (-(-1 + t) (1 + t) (363 + 10310 t^2 + 58673 t^4 + 
  101548 t^6 + 58673 t^8 + 10310 t^10 + 363 t^12) + 
140 (1 + t^2) (1 + 48 t^2 + 393 t^4 + 832 t^6 + 393 t^8 + 48 t^10 +
   t^12) Log[t]) (t - t^3 + (-1 + t^4) ArcTanh[t] + 
t^2 (-4 PolyLog[2, t] + PolyLog[2, t^2]))^2

and would like to obtain a high-precision estimate of its integral over [0,1] (which I would then input, say to WolframAlpha, to check for a possible exact value). I've encountered numerical problems near t = 1.

$\endgroup$
7
  • $\begingroup$ How high a precision do you need? $\endgroup$
    – bbgodfrey
    Dec 15, 2016 at 3:22
  • $\begingroup$ Thanks bbgodfrey! Well, I'm basically (perhaps wildly) speculating that there might be some underlying exact value of note (maybe even a rational number), based on some prior considerations. So, if WolframAlpha, say, doesn't indicate such a value for a given precision, I could just try to get more numerical precision and try again. Of course, such a process could not go on for ever. I would imagine that perhaps an estimate accurate to say 15 places might settle the issue. $\endgroup$ Dec 15, 2016 at 3:35
  • $\begingroup$ Try 0.450160328041638434796903399409, but I am not aware of any capabilities that WolframAlpha has that Mathematica does not. $\endgroup$
    – bbgodfrey
    Dec 15, 2016 at 3:37
  • $\begingroup$ Can you maybe describe the provenance of this function? $\endgroup$ Dec 15, 2016 at 6:48
  • $\begingroup$ For a possible exact value: Can Mathematica propose an exact value based on an approximate one? and an example application. Try also RootApproximant with ToRadicals. $\endgroup$
    – corey979
    Dec 15, 2016 at 7:55

1 Answer 1

1
$\begingroup$
f[t_] = (1/(35 \[Pi]^3 (-1 + t^2)^13)) 65536 t (-(-1 + t) (1 + 
        t) (363 + 10310 t^2 + 58673 t^4 + 101548 t^6 + 58673 t^8 + 
        10310 t^10 + 363 t^12) + 
     140 (1 + t^2) (1 + 48 t^2 + 393 t^4 + 832 t^6 + 393 t^8 + 
        48 t^10 + t^12) Log[t]) (t - t^3 + (-1 + t^4) ArcTanh[t] + 
      t^2 (-4 PolyLog[2, t] + PolyLog[2, t^2]))^2;

High WorkingPrecision is required to Plot

Plot[f[t], {t, 0, 1}, WorkingPrecision -> 30]

enter image description here

Table[
   {wp, NIntegrate[f[t], {t, 0, 1},
      WorkingPrecision -> wp,
      MaxRecursion -> Infinity] //
     N[#, 15] &}, {wp, 15, 40, 
    5}] //
  Grid // Quiet

enter image description here

So the integral stabilizes to 15 decimal places at a WorkingPrecision of around 35

(int = NIntegrate[f[t], {t, 0, 1}, WorkingPrecision -> 35, 
     MaxRecursion -> Infinity]) // N[#, 15] & // Quiet

(*  0.450160328041638  *)

Using Round to rationalize

intr = int // Round[#, 10^-15] &

(*  225080164020819/500000000000000  *)

intr // N[#, 15] &

(*  0.450160328041638  *)

Using Rationalize

intr2 = Rationalize[int, 10*^-16]

(*  18677965/41491806  *)

intr2 // N[#, 15] &

(*  0.450160328041638  *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.