3
$\begingroup$

I have this system of equations. I want to express all variables in terms of x as you can see. x is a parameter.

Solve[{y (z - x) == x^6, x zg - z zg == x z^2 za zb - x z za zb zg, 
za zg - zb zg == z za zb - z za^2 zb, zb - zg == z za zb - z zb^2, 
za zb (z - zg) == zg (-zb + zg), za > 0, zb > 0, zg > 0, z > 0}, {y, za, zb, zg, z}, Reals]

However Mathematica doesn't know how to solve it. Solutions show me something called Root and I can't make sense out of any of the expressions I get. What I get is:

y -> ConditionalExpression[((
x^6)/(-x + 
Root[-x + 
2 x^2 + (1 - 3 x - x^2) #1 + (1 + 2 x - 4 x^2) #1^2 + (-1 + 
 5 x - x^2) #1^3 + (-1 + x - x^2) #1^4 + x^2 #1^5 &, 3]))

I also tried using reduce which gives me a set of solutions for y:

y == Root[
x^26 + (-x^18 + x^19 - x^20 + 5 x^21) #1 + (-x^12 + x^13 + 3 x^14 - 
   4 x^15 + 10 x^16) #1^2 + (x^6 - x^7 + 5 x^8 + 3 x^9 - 6 x^10 + 
   10 x^11) #1^3 + (1 - x + 3 x^3 + x^4 - 4 x^5 + 
   5 x^6) #1^4 + (-1 + x) #1^5 &, 1] 

I've read this thread: How do I work with Root objects? but it doesn't solve my problem since I have this free parameter x that ruins everything. For example if I try ToRadicals or numerical value I don't get anything. How do I make sense of it? How can I proceed to get the full expression for y in terms of x without Root? I tried FindInstance but it doesn't work in my case since I have this free parameter x. If this helps I'm only interested in y, the rest of the parameters don't really matter. Any help is greatly appreciated.

$\endgroup$
  • 2
    $\begingroup$ The Root part is a root to a 5th degree polynomial. In general, they cannot be expressed in terms of radicals. Whether or not your particular solution can, for all x, is not a question I can figure out in my head. Probably not, though. One can probably solve it with this, which I believe solves it in terms of theta functions. But Root is probably easier to work with. $\endgroup$ – Michael E2 Dec 11 '16 at 19:45
  • 1
    $\begingroup$ Root[] is like any other numeric function such as Sin[]. There are algorithms to compute their values to any number of decimals, there are algorithms for simplifying and combining them. Just treat like you would f[x]. -- Your 2nd question confuses me: Do you want to work with Root or without it? If without, see my first comment. $\endgroup$ – Michael E2 Dec 11 '16 at 20:08
  • 1
    $\begingroup$ What both Michael and the answer you reference are saying is that it is not possible to express the roots of a general 5th order polynomial in terms of radicals. Root represents a number and you can manipulate it symbolically like any other number. $\endgroup$ – Szabolcs Dec 11 '16 at 20:31
  • 1
    $\begingroup$ As I said, see my first comment. Perhaps it can be done "in terms of theta functions" (link above). -- Related perhaps: (109578), not a solution, just relevant to learning to live with Root as a closed-form expression. $\endgroup$ – Michael E2 Dec 11 '16 at 20:32
  • 1
    $\begingroup$ I can't do what I want without explicit form in terms of x. As I said: I want to have algebraic curve defined by zero locus of some polynomial y^n-solution = 0. So any power of y would work, as long as It's a closed expression even with square root or something (If I would have expression with square root then I could manipulate it to get what I want). Unfortunately a method from the last link on Roots (the one on how to live with them) doesn't give me a nice expression like it gives there. $\endgroup$ – Caims Dec 11 '16 at 20:51
5
$\begingroup$

From a comment, it seems maybe the OP would like to rationalize the expression:

Product[y - 
   Root[x^26 + (-x^18 + x^19 - x^20 + 5 x^21) #1 + (-x^12 + x^13 + 
         3 x^14 - 4 x^15 + 10 x^16) #1^2 + (x^6 - x^7 + 5 x^8 + 
         3 x^9 - 6 x^10 + 10 x^11) #1^3 + (1 - x + 3 x^3 + x^4 - 
         4 x^5 + 5 x^6) #1^4 + (-1 + x) #1^5 &, i], {i, 
   5}] // FullSimplify
(*
(1/(-1 + x))(x^26 + x^18 (-1 + x - x^2 + 5 x^3) y + 
  x^12 (-1 + x (1 + x (3 + 2 x (-2 + 5 x)))) y^2 + 
  x^6 (1 + x (-1 + x (5 + x (3 + 2 x (-3 + 5 x))))) y^3 + (1 - x + 
     3 x^3 + x^4 - 4 x^5 + 5 x^6) y^4 + (-1 + x) y^5)
*)

Set this equal to zero to represent the locus. Note that the product may or may not have introduced extraneous solutions.


Addendum

Silly me, this is equivalent to, with less work, the following:

First[
  Root[x^26 + (-x^18 + x^19 - x^20 + 5 x^21) #1 + (-x^12 + x^13 + 
        3 x^14 - 4 x^15 + 10 x^16) #1^2 + (x^6 - x^7 + 5 x^8 + 
        3 x^9 - 6 x^10 + 10 x^11) #1^3 + (1 - x + 3 x^3 + x^4 - 
        4 x^5 + 5 x^6) #1^4 + (-1 + x) #1^5 &, 1]
  ]@y
(*
x^26 + (-x^18 + x^19 - x^20 + 5 x^21) y + (-x^12 + x^13 + 3 x^14 - 
    4 x^15 + 10 x^16) y^2 + (x^6 - x^7 + 5 x^8 + 3 x^9 - 6 x^10 + 
    10 x^11) y^3 + (1 - x + 3 x^3 + x^4 - 4 x^5 + 5 x^6) y^4 + (-1 + 
    x) y^5
*)

There is still the general caveat about rationalizing leads potentially to extraneously solutions.

$\endgroup$
  • $\begingroup$ That's exactly what I want, I'm really sorry for not being more clear. Thank you very much, you saved the day! $\endgroup$ – Caims Dec 11 '16 at 21:20
  • $\begingroup$ By the way, there's no extra problem that you mentioned, everything is fine. $\endgroup$ – Caims Dec 11 '16 at 21:25
  • $\begingroup$ @Caims No problem & you're welcome. I'll leave the warning in case someone else tries the same thing on their problem. It's like squaring both sides of an equation: sometimes you get extra solutions, sometimes not. $\endgroup$ – Michael E2 Dec 11 '16 at 21:30
2
$\begingroup$

I'm not sure this is exactly what you are looking for, but one approach is to define y (and your others) as functions of x and then plot to see what it looks like. For example:

y[x_] := Root[x^26 + (-x^18 + x^19 - x^20 + 5 x^21) #1 + 
         (-x^12 + x^13 + 3 x^14 - 4 x^15 + 10 x^16) #1^2 + 
         (x^6 - x^7 + 5 x^8 + 3 x^9 - 6 x^10 + 10 x^11) #1^3 + 
         (1 - x + 3 x^3 + x^4 - 4 x^5 + 5 x^6) #1^4 + (-1 + x) #1^5 &, 1];
Plot[y[x], {x, -5, 5}]

enter image description here

$\endgroup$
  • $\begingroup$ Unfortunately, I need the expression for zero locus of the polynomial that I will get from the solution for y. $\endgroup$ – Caims Dec 11 '16 at 19:10

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.