Using DSolve for a coupled differential equation

Question

I'm trying to solve (using the DSolve command) the following system

$\psi_1''[x]+(E_1-E-xV)\psi_1[x]-i\psi_2'[x]=0$

$\psi_2''[x]+(E_2-E-xV)\psi_2[x]-i\psi_1'[x]=0$

However, seems the Mathematica cannot manage to give a solution. Am I doing something wrong? Do you guys have any suggestions concerning some kind of transformation which will give a simpler equation to be solved?

DSolve[{ψ1''[x] + (-E1 - En - x V0) ψ1[x] - I ψ2'[x] == 0,
ψ2''[x] + (-E2 - En - x V0) ψ2[x] - I ψ1'[x] == 0},  {ψ1, ψ2}, x]

Thanks too much!

Best,

Answer 1

Actually it is not true that DSolve cannot solve it: just consider the uncoupled system formed by the sum $s[t]$ and the difference $d[t]$ of $\Psi_1[t]$ and $\Psi_2[t]$:

DSolve[{s''[t] + (e1 + e2 - 2 e - t v) s[t] - I s'[t] == 0, 
d''[t] + (e1 - e2) d[t] + I d'[t] == 0}, {s, d}, t]

with solution:

(*{{s -> Function[{t}, 
    E^((I t)/2)
       AiryAi[(1/4 (-1 + 8 e - 4 e1 - 4 e2) + t v)/v^(2/3)] C[1] + 
     E^((I t)/2)
       AiryBi[(1/4 (-1 + 8 e - 4 e1 - 4 e2) + t v)/v^(2/3)] C[2]], 
  d -> Function[{t}, 
    E^(1/2 (-I - Sqrt[-1 - 4 e1 + 4 e2]) t) C[3] + 
     E^(1/2 (-I + Sqrt[-1 - 4 e1 + 4 e2]) t) C[4]]}}*)

Now you can get the solution for the original functions.

Answer 2

One way to find a solution easily is to go for numerical solution using NDSolve.

Here, I have choose random values for the parameters.

E1 = E2 = En = V0 = 1; L1 = 5;
sol = NDSolve[{ψ1''[x] + (-E1 - En - x V0) ψ1[x] - I ψ2'[x] == 0, 
ψ2''[x] + (-E2 - En - x V0) ψ2[x] - I ψ1'[x] == 0, ψ1[0] == 0, ψ1[L1] == 0, ψ2[0] == 0, 
ψ2[L1] == 0}, {ψ1, ψ2}, {x, 0, L1}];

Finally, plotting the results,

Plot[Evaluate[{Re[ψ1[x]], Re[ψ2[x]], Im[ψ1[x]],Im[ψ2[x]]} /. sol], {x, 0, L1}, 
PlotRange -> All, Frame -> True,PlotStyle -> {Red, Green, Directive[Blue, Dashed], 
Directive[Black, Dashed]}]