1
$\begingroup$

I am evaluating a parametric inequality conditional on some assumptions on the parameters. In the simplest form, here, I am assuming the numerator and the denominator are positive:

Simplify[(a/b) > 0 , a > 0 && b > 0]

This gives me "TRUE". But when I do the same for my big equations it doesn't give me "TRUE"; it just shows my equation is positive (i.e it just gives me (a/b)>0 as a result or (a/b)<0 if I write (a/b)<0 in above). Here is my code:

Simplify[(θ (-(-1 + β) (1 + p - p α + (-1 + p) β) ρ - 
   (-1 +  p) (f p + (-1 + β)^2) β Subscript[g, B]))/
    ((1 - p) (f p + (-1 + β)^2) β + (-1 + β) (1 + p - p α + (-1 + p) β) θ) >  0, 
  θ (-(-1 + β) (1 + p - p α + (-1 + p) β) ρ - 
     (-1 + p) (f p + (-1 + β)^2) β Subscript[g, B]) > 0 && 
  ((1 - p) (f p + (-1 + β)^2) β + (-1 + β) (1 + p - p α + (-1 + p) β) θ) > 0]

I am going to assume other conditions on the parameters instead of the positivity of numerator and the denominator. I have just started with these two conditions to make sure it works, but it can't evaluate my expression.

Thanks,

$\endgroup$
  • $\begingroup$ What do you expect as an answer? Without conditions on the various parts of the expression, there is no way to tell whether it's greater or less than zero. Consider the simplest case: Simplify[a>0]. Is this true? False? With no conditions on a, there is no possible simplification. $\endgroup$ – bill s Nov 30 '16 at 22:33
  • $\begingroup$ I am adding conditions by assuming that both numerator and the denominator are positive. I expect to give me "TRUE" as an answer like the answer to the simplest form that I have mentioned. The simple form (a/b) works but it doesn't work for my inequality! $\endgroup$ – Hossein Nov 30 '16 at 22:38
  • $\begingroup$ The expression I have posted is still in the format of Simplify[(a/b) > 0 , a > 0 && b > 0]. Aren't a>0 && b>0 conditions? $\endgroup$ – Hossein Nov 30 '16 at 22:52
  • $\begingroup$ I have made the expression simpler. Now it is a ratio>0 followed by two conditions: numerator >0 && denominator>0. It still gives me the ratio>0 as a result not True. Even if I make one of the numerator or denominator negative, the result remains the same: a/b>0 $\endgroup$ – Hossein Nov 30 '16 at 23:24
  • $\begingroup$ Did you try FullSimplify? This now seems to simplify it somewhat. Reduce also gives a whole slew of conditions. $\endgroup$ – bill s Nov 30 '16 at 23:29
1
$\begingroup$

As in these related Q/As (Simplifying expressions with head Max and Using Inequality Assumptions) the number of variables in your non-linear expression exceeds the limit set by the system sub-option "AssumptionsMaxNonlinearVariables" (which is 4). Increasing this option value to 10 gives the expected result.

SetSystemOptions["SimplificationOptions"->{"AssumptionsMaxNonlinearVariables" -> 10}];

Simplify[(θ (-(-1 + β) (1 + p - p α + (-1 + p) β) ρ - 
     (-1 + p) (f p + (-1 + β)^2) β Subscript[g, B]))/
     ((1 - p) (f p + (-1 + β)^2) β + (-1 + β) (1 + p - p α + (-1 + p) β) θ) > 0, 
 θ (-(-1 + β) (1 + p - p α + (-1 + p) β) ρ - 
     (-1 + p) (f p + (-1 + β)^2) β Subscript[g, B]) > 0 &&
 ((1 - p) (f p + (-1 + β)^2) β + (-1 + β) (1 + p - p α + (-1 + p) β) θ) > 0]

True

To set the option back to its default value use

 SetSystemOptions["SimplificationOptions" -> {"AssumptionsMaxNonlinearVariables" -> 4}];
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.