How to make ClipPlanes only affect one of the 3D objects?

Question

In order to show the maximum hemisphere inscribed to a unit cuboid, I use the following code:

Show[ContourPlot3D[
  30 - 12 Sqrt[6] + x (-6 + 2 Sqrt[6] + x) + y (-6 + 2 Sqrt[6] + y) + 
    z (-6 + 2 Sqrt[6] + z) == 0, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, 
  Mesh -> None, PlotTheme -> "Classic", 
  ClipPlanes -> -{1, 1, 1, 3 (Sqrt[6] - 3)}, 
  ClipPlanesStyle -> {Opacity[.5]}], 
 Graphics3D[{Red, Ball[{1, 4 - 3 Sqrt[3/2], 4 - 3 Sqrt[3/2]}, .1]}, 
  Boxed -> False], 
 Graphics3D[{Green, 
   Sphere[{5 - 2 Sqrt[6], 2 - Sqrt[3/2], 2 - Sqrt[3/2]}, .1]}, 
  Boxed -> False]
 ]

I add two sphere /ball 3D objects in order to indicate the edge of the hemisphere. But I don't want the balls being clipped too.

How can I avoid it?

Answer 1

ClipPlanes can be limited to specific primitives. In this case the easiest way is probably to pass them in as part of the contour style:

Show[
    ContourPlot3D[
        30 - 12 Sqrt[6] + x (-6 + 2 Sqrt[6] + x) + y (-6 + 2 Sqrt[6] + y) + 
        z (-6 + 2 Sqrt[6] + z) == 0, {x, 0, 1.1}, {y, 0, 1}, {z, 0, 1}, 
        Mesh -> None, PlotTheme -> "Classic", BoundaryStyle -> None,
        ContourStyle -> Directive[{
            (* coerce to floating point because of, um, reasons *)
            ClipPlanes -> -{1, 1, 1, 3 (Sqrt[6] - 3.)}, 
            ClipPlanesStyle -> {Opacity[.5]}
            }]
        ], 
    Graphics3D[{Red, Ball[{1, 4 - 3 Sqrt[3/2], 4 - 3 Sqrt[3/2]}, .1]}, 
        Boxed -> False], 
    Graphics3D[{Green, Sphere[{5 - 2 Sqrt[6], 2 - Sqrt[3/2], 2 - Sqrt[3/2]}, .1]}, 
        Boxed -> False]
]