One inequality with two variables

Question

I would just like to know if this:

((a - b)/(b*Log[b])) - Log[Log[a]] + Log[Log[b]]

exceeds 0 for any combination of a and b, being both variables positive integers.

I have tried to compute it on Mathematica but I only get hundreds of errors.

What would be the way to know if there is a solution to

((a - b)/(b*Log[b])) - Log[Log[a]] + Log[Log[b]]<0

Answer 1

A mathematical proof would be best, but Mathematica can provide some evidence against the statement that

f[a_, b_] := ((a - b)/(b*Log[b])) - Log[Log[a]] + Log[Log[b]]

is negative for any integer a, b.

A straightforward way would be to do

NMinimize[{f[a, b], a > 1, b > 1}, {a, b}, Integers]

{0., {a -> 4, b -> 4}}

Indeed, f[a, b]==0 for a == b. Dropping the condition Integers,

NMinimize[{f[a, b], a > 1, b > 1}, {a, b}]

{-1.11022*10^-16, {a -> 3.71536, b -> 3.71536}}

gives a numerical zero.

A ContourPlot:

ContourPlot[f[a, b], {a, 1, 10}, {b, 1, 10}, PlotLegends -> Automatic]

hints that indeed there are no truly negative values of f[a, b] for a, b >= 1.

A contour highlighting f[a, b]==0:

ContourPlot[f[a, b], {a, 1, 10}, {b, 1, 10}, Contours -> {0}]

confirms that 0 is the smallest value attained by f[a, b] for positive integer a, b.

Answer 2

eq = ((a - b)/(b*Log[b])) - Log[Log[a]] + Log[Log[b]];

First try with FindInstance

FindInstance[eq < 0, {a, b}, Integers]

FindInstance::nsmet: The methods available to FindInstance are insufficient to find the requested instances or prove they do not exist.

Second try:

data = Flatten[Table[{a, b, eq}, {a, 2, 100}, {b, 2, 100}], 1] // N;
MinimalBy[data, Last]

probably never less than zero.

Answer 3

For this case you can try a graphical method. For example:

RegionPlot[((a - b)/(b*Log[b])) - Log[Log[a]] + Log[Log[b]] > 0, {a, 
 0, 10}, {b, 0, 10}] 

It shows the region on the ab plane where the inequality is satisfied. Of course you can change the limits for a and b according to your needs. I've got a>1 and b>1 as a solution.