5
$\begingroup$

I have:

Clear[z]
Solve[z^4 == 1 - Sqrt[3] I, z] // ComplexExpand

Which produces these solutions:

{{z -> -(1/(2 2^(1/4))) - Sqrt[3]/(2 2^(1/4)) + 
    I (-(1/(2 2^(1/4))) + Sqrt[3]/(2 2^(1/4)))}, {z -> 
   1/(2 2^(1/4)) - Sqrt[3]/(2 2^(1/4)) + 
    I (-(1/(2 2^(1/4))) - Sqrt[3]/(2 2^(1/4)))}, {z -> -(1/(
     2 2^(1/4))) + Sqrt[3]/(2 2^(1/4)) + 
    I (1/(2 2^(1/4)) + Sqrt[3]/(2 2^(1/4)))}, {z -> 
   1/(2 2^(1/4)) + Sqrt[3]/(2 2^(1/4)) + 
    I (1/(2 2^(1/4)) - Sqrt[3]/(2 2^(1/4)))}}

What would be the easiest way to convert these to a list of arrows to plot in the Argand plane. For example, the cube roots of -1:

Graphics[{
  Circle[],
  Blue, Thick,
  Arrow[{{0, 0}, {-1, 0}}],
  Arrow[{{0, 0}, {1/2, Sqrt[3]/2}}],
  Arrow[{{0, 0}, {1/2, -Sqrt[3]/2}}]
  }, Axes -> True, ImageSize -> Small]

Produces this image:

enter image description here

But I am looking for a cute way to convert all the data in the first problem, $z^4=1-\sqrt3 i$, into a list of arrows.

$\endgroup$

2 Answers 2

9
$\begingroup$
sol = z /. Solve[z^4 == 1 - Sqrt[3] I, z] // ComplexExpand

enter image description here

coords = N @ ReIm @ sol (* N not needed, I just wanted a compact output *)

{{-1.14869, 0.307789}, {-0.307789, -1.14869}, {0.307789, 1.14869}, {1.14869, -0.307789}}

arr = Arrow[{{0, 0}, #}] & /@ coords

{Arrow[{{0, 0}, {-1.14869, 0.307789}}], Arrow[{{0, 0}, {-0.307789, -1.14869}}], Arrow[{{0, 0}, {0.307789, 1.14869}}], Arrow[{{0, 0}, {1.14869, -0.307789}}]}

For the circle:

{r = Abs[1 - Sqrt[3] I]^(1/4), N@r}

{2^(1/4), 1.18921}

Graphics[{Circle[{0, 0}, r], Blue, Thick, arr}, Axes -> True, 
 AxesLabel -> {"Re z", "Im z"}]

enter image description here

$\endgroup$
3
  • 1
    $\begingroup$ This is a really well explained explanation. I'd like to thank you for all the intermediate steps. They greatly helped my understanding. $\endgroup$
    – David
    Nov 14, 2016 at 19:11
  • $\begingroup$ I'm glad I could help :) $\endgroup$
    – corey979
    Nov 14, 2016 at 21:30
  • 1
    $\begingroup$ I just made a simplifying edit; if you do not like this revert the change or edit as you see fit. IMHO multiple baroque alternatives do not enhance this otherwise concise answer. $\endgroup$
    – Mr.Wizard
    Nov 20, 2016 at 19:02
4
$\begingroup$

Really just for fun to illustrate the geometric effect: $z^n=c$

f[c_, n_] := 
 Table[ReIm@N[Abs[c]^(1/n) Exp[Arg[c] I/n + 2 Pi I j/n]], {j, 0, n - 1}]
Manipulate[
 Module[{roots = f[Complex @@ p, n]},
  Graphics[{Circle[], Red, Circle[{0, 0}, Norm@p], Arrow[{{0, 0}, p}],
     Blue, Arrow[{{0, 0}, ##}] & /@ roots, Pink, Opacity[0.5], 
    Disk[{0, 0}, 0.5, {0, Arg[Complex @@ p]}],
    LightBlue,
    Disk[{0, 0}, Norm@p, {0, ArcTan @@ roots[[1]]}]},
   PlotLabel -> 
    Style[StringForm["\!\(\*SuperscriptBox[\(z\), \(`1`\)]\)=`2`", n, 
      Complex @@ p], 20],
   Axes -> True,
   PlotRange -> Table[{-2, 2}, 2]
   ]],
 {{p, {1, 0}}, {-2, -2}, {2, 2}}, {n, Range[2, 7]}]

Selected examples:

enter image description here

enter image description here

enter image description here

$\endgroup$
1
  • $\begingroup$ Really nice example. I'm gonna have to study this one. Thanks ever so much for all of your responses. $\endgroup$
    – David
    Nov 15, 2016 at 6:58

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.