2
$\begingroup$

I would like to integrate

Integrate[x*E^(x^2 + y^2 + z^2) Boole[x^2 + y^2 + z^2 <= 1], {x,0,1}, {y,0,1}, {z,0,1}]

However Mathematica gives me

E*Integrate[x*DawsonF[Sqrt[1 - x^2 - y^2]], {x, 0, 1}, {y, 0, Sqrt[1 - x^2]}]

instead of a closed form. Using NIntegrate does match numerically the actual answer, Pi/8. How can I evaluate this integral without using spherical coordinates? I've tried with Assumptions -> x>=0 && y>=0 && z>=0, but that does not help.

$\endgroup$
2
$\begingroup$

This works:

Integrate[
 x*E^(x^2 + y^2 + z^2) Boole[x >= 0 && y >= 0 && z >= 0],
 {x, y, z} ∈ Ball[]]
(*  π/8  *)

Also this:

Integrate[Abs@x*E^(x^2 + y^2 + z^2), {x, y, z} ∈ Ball[]]/8
(*  π/8  *)
$\endgroup$
1
$\begingroup$

Using NIntegrate

rgn = ImplicitRegion[
   x^2 + y^2 + z^2 <= 1 && x >= 0 && y >= 0 && z >= 0,
   {x, y, z}];

Pi*RootApproximant[
  NIntegrate[
    x*E^(x^2 + y^2 + z^2),
    {x, y, z} ∈ rgn]/
   Pi]

(*  π/8  *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.