# integral over a region boundary

I want to integrate a complex function over a boundary of a region:

$$-\frac{i}{v}\oint_\Gamma \exp(-2\pi i(ux+vy))\,dx,$$

where $\Gamma$ is the closed boundary of a region and $y = f(x)$.

I know that MMA can extract the boundary of a region. For instance:

R = RegionBoundary[Disk[]];


returns the circumference of the unit circle. Therefore if I do:

Integrate[1, {x, y} ∈ R]


gives its length: $2\pi$.

No problem thus far as I understanding that the integral is a contour integral. I mean, it is integrating over the boundary of the region R.

Now, if I do the following:

Assuming[v >= 0 && u >= 0, -I/v*Integrate[Exp[-2 π I (u*x + v*y)], {x, y} ∈ R] // FunctionExpand]


it should return:

2 π BesselJ[1, 2 π Sqrt[u^2 + v^2]]/Sqrt[u^2 + v^2]


but it doesn't.

Am I not understanding correctly how to extract the boundary of a region to use it in a integral along that contour?, or am I not doing the integration well?

• If I place the FunctionExpand outside of integral, I get an answer in terms of BesselJ. – Chip Hurst Nov 8 '16 at 20:19
• @ChipHurst you mean you obtain exactly what I am expecting? – José Antonio Díaz Navas Nov 8 '16 at 20:21
• No, I get a different expression. Numerically verifying, I believe your proposed solution is incorrect and the one Mathematica returns is correct. – Chip Hurst Nov 8 '16 at 20:24
• @ChipHurst I have check my expected result for typos. It is correct. Do you obtain 2 \[Pi] BesselJ[0, 2 \[Pi] Sqrt[u^2 + v^2]] ? – José Antonio Díaz Navas Nov 8 '16 at 20:30
• Let us take $(x,y)=(\cos\theta,\sin\theta)$ in a circumference of unit radius, and $(u,v)=(\rho\cos\phi,\rho\sin\phi)$. Therefore my integral is $-i/v\int_0^{2\pi}\exp[-i \rho\cos(\theta-\phi)](-\sin\theta)d\theta$, and thus the result is $2\pi J_1(\rho)/\rho$. I still need a reason of why my solution is wrong and that of MMA is not. – José Antonio Díaz Navas Nov 9 '16 at 17:27

As I said in the comments, I believe Mathematica is correct and your proposed solution is not.

sol[u_, v_] = -I/v*Integrate[Exp[-2 π I (u*x + v*y)], {x, y} ∈ Circle[]] // FunctionExpand


We can test this solution and your solution v.s. numerical integration:

With[{u = 1, v = 2},
{
-I/v*NIntegrate[Exp[-2 π I (u*Cos[t] + v*Sin[t])], {t, 0, 2π}],
sol[u, v],
BesselJ[1, 2 π Sqrt[u^2 + v^2]]/Sqrt[u^2 + v^2]
}
] // N // Chop

{0. - 0.516032 I, 0. - 0.516032 I, 0.0631519}


Testing many random values:

(
With[{u = #1, v = #2},
{
sol[u, v] + I/v*NIntegrate[Exp[-2 π I (u*Cos[t] + v*Sin[t])], {t, 0, 2π}],
sol[u, v] - BesselJ[1, 2 π Sqrt[u^2 + v^2]]/Sqrt[u^2 + v^2]
}
] // N // Chop
) & @@@ RandomReal[{0, 10}, {10, 2}]

{{0, -0.0158981 + 2.76255 I},
{0, 0.0323925 - 0.345255 I},
{0, -0.112578 + 0.282299 I},
{0, -0.12562 - 0.183919 I},
{0, -0.0101141 + 0.128913 I},
{0, 0.0197579 + 0.0172606 I},
{0, -0.00352234 - 0.11468 I},
{0, 0.00125063 + 0.105634 I},
{0, 0.0148865 + 0.0448442 I},
{0, -0.00837518 - 0.0581776 I}}

• That I/v looks out of place too since it makes the integrand non-symmetric to the exchange of u and v. The proposed solution is symmetric. But the proposed solution isn't good even if we remove the I/v. – Szabolcs Nov 9 '16 at 15:05
• My "written" solution above in a comment does not agree with MMA and with this. – José Antonio Díaz Navas Nov 10 '16 at 10:27