# Animate a circle “rolling” along a complicated 3D curve

I need to know how to plot and animate a circle "rolling" along this pretty complicated 3D parametric curve.

r[t_] := {4 Sin[t] Cos[4 t], 3 Sin[t] Sin[4 t], 3 Sin[t]};
ParametricPlot3D[r[t], {t, 0, 2 \[Pi]}]


I really have no clue where to start. I can animate basic things like drawing on a curve but not something like this.

I have the unit vectors but will refrain from posting here since they are quite lengthy. T(t) is the tangent unit vector and N(t) is the normal unit vector.

0 < u < 2pi

Find an equation for the circle C_u of radius 1 that's centered at r(u) + N(u) and contained in the unit tangent vector and unit normal vector planes.

Plot the circles, u = 1/2 and u = pi with the curve.

Animate the plots of all the circles C_u, 0 < u < 2pi, with the curve. It should appear to be wheel rolling along the curve in the normal position. EDIT: The circle must be oriented "flat" (parallel to the x-plane I believe) the entire time. The first reply is really good, it just needs to be oriented flat and inside the curve at all times.

This is baffling

Thanks

EDIT: The editor won't let me put a greeting at the beginning. Also if you need me to post the unit vectors I will gladly.

EDIT 2: Here is my attempt of trying to plot just the circle:

Manipulate[ParametricPlot3D[{Circle[{t, r[t]}, 1]}, PlotRange -> Automatic], {t, 0, 2 \[Pi]}]


EDIT 3: The circle must be oriented "flat" (parallel to the x-plane I believe) the entire time. Sorry I forgot to mention this

EDIT

As OP wishes (and as Rahul correctly points out) my original answer puts unit circle in TB plane (my error as labels suggest) and what is desired is TN plane.

pp = ParametricPlot3D[r[t], {t, 0, 2 \[Pi]}]
fs = FrenetSerretSystem[r[t], t];
tan[s_] := fs[[2, 1]] /. t -> s
nrm[s_] := fs[[2, 2]] /. t -> s
cir[u_] :=
Table[r[u] + Cos[j] tan[u] + (Sin[j] + 1) nrm[u], {j, 0, 2 Pi, 0.1}]


Export gif of:

Table[
Show[
Graphics3D[{Yellow, PointSize[0.04], Point[pnts[v]],
Thickness[0.02], Red, Line[cir[v]]}], pp,
PlotRange -> {{-5, 5}, {-5, 5}, {-5, 5}}, Boxed -> False,
Background -> Black], {v, 0, 2 Pi, 0.1}]


It is relatively straightforward to slide a circle, e.g.

pp = ParametricPlot3D[r[t], {t, 0, 2 π}];
fs = FrenetSerretSystem[r[t], t];
tan[s_] := fs[[2, 1]] /. t -> s
bnrm[s_] := fs[[2, 3]] /. t -> s
cir[u_] :=
Table[r[u] + Cos[j] tan[u] + (Sin[j] + 1) bnrm[u], {j, 0, 2 Pi, 0.1}]


So,

Manipulate[
Show[Graphics3D[{Red, Thickness[0.02], Line[cir[v]]}], pp,
PlotRange -> {{-4, 4}, {-4, 4}, {-5, 5}}, Background -> Black,
Boxed -> False], {v, 0, 2 Pi}]


To simulate rolliing (the arc length expression was derived from ArcLength function:

al[u_] :=
NIntegrate[\[Sqrt](9 Cos[t]^2 + (12 Cos[4 t] Sin[t] +
3 Cos[t] Sin[4 t])^2 + (4 Cos[t] Cos[4 t] -
16 Sin[t] Sin[4 t])^2), {t, 0, u}]
p[t_] := r[t] + Sin[al[t]] tan[t] + (1 + Cos[al[t]]) bnrm[t]


Visualizing:

Manipulate[
Show[
Graphics3D[{Yellow, PointSize[0.04], Point[p[v]], Thickness[0.02],
Red, Line[cir[v]]}], pp, PlotRange -> {{-5, 5}, {-5, 5}, {-5, 5}},
Boxed -> False, Background -> Black], {v, 0, 2 Pi}]


• There are sections of your first GIF where the red circle disappears behind a static black square. I think the image might be a little bit corrupt (missing data on animation layers) because there's no reason for the actual function to do that. (Right?) – wizzwizz4 Oct 25 '16 at 8:35
• @wizzwizz4 the gif is a screen capture. Thank you for your comment. If it is not a defect related to capture then I am sure better quality and better approaches are feasible. In reflection, if you are referring to 'cut off' this relates to plot range. I was too time poor to edit. Feel free to improve as you see fit.:) – ubpdqn Oct 25 '16 at 8:40
• I can see it at ~4.9 and ~1.5 on the first image. Unfortunately I don't have Mathematica and so can't re-record it myself. As long as it's not a problem with the function and just the image it doesn't really affect the answer at all. – wizzwizz4 Oct 25 '16 at 8:43
• @wizzwizz4 I appreciate you pointing it out. I think it is the range issue. You can see I extended the plot range in the second gif which I think has no such defects. There can be other ways to achieve the goal and you (when you have access to MMA) or others can do them. There are other ways to make my answer look nicer. I just wanted to propose a start. :) – ubpdqn Oct 25 '16 at 8:48
• @naanman you could use the tangent and binormal unit vector as the basis for circle. Good luck with achieving your aim. :) – ubpdqn Oct 26 '16 at 0:54