Solve equations that give {} result with complex quantity

Question

I tried to find the roots of the following equation by using Solve:

Solve[8/(π u (-I a + γ) Sqrt[1 + 
    (h^2 v^2 u^2)/(-I a + γ)^2]) + 
    (16 (-I a + γ) (1 - Sqrt[1 + 
      (h^2 v^2 u^2)/(-I a + γ)^2]))/(h^2 π v^2 u^3) == 0, u]

but I did not get any result, it was only {}. I redefined (-I a + γ) as c based on some instructions I found here, but I got nothing.

Answer 1

A result of {} from Solve indicates that Solve thinks the solution set is empty. We can see that this is so, if we rationalize the left-hand side of the equation:

lhs = 8/(π u (-I a + γ) Sqrt[1 + (h^2 v^2 u^2)/(-I a + γ)^2]) +
  (16 (-I a + γ) (1 - Sqrt[1 + (h^2 v^2 u^2)/(-I a + γ)^2]))/(h^2 π v^2 u^3);
conjugates = lhs /. {{e_ :> e}, {r : Sqrt[_] :> -r, r : 1/Sqrt[_] :> -r}};
Times @@ conjugates // Expand // Simplify
(* -(64/(π^2 u^2 (-a^2 + h^2 u^2 v^2 - 2 I a γ + γ^2)))  *)

Since the numerator is a constant 64, the equation lhs == 0 cannot be satisfied.

One might put the terms together and set the numerator equal to zero. But this yields a result that makes lhs undefined:

Solve[Numerator@Together@eqn == 0, u]
lhs /. %
(*
  {{u -> 0}}
  {Indeterminate}
*)

Whether or not this can be considered a valid solution depends on whether clearing the denominator can be justified in the problem in which the equation arose.

Answer 2

When you first do a few transformations by hand, you get a good result:

    8/(π u (-I a + γ) Sqrt[
1 + (h^2 u^2 v^2)/(-I a + γ)^2]) + (
16 (-I a + γ) (1 - Sqrt[
 1 + (h^2 u^2 v^2)/(-I a + γ)^2]))/(h^2 π u^3 v^2) == 0

to

    8/(π u (-I a + γ) Sqrt[
1 + (h^2 u^2 v^2)/(-I a + γ)^2]) == -((
16 (-I a + γ) (1 - Sqrt[
 1 + (h^2 u^2 v^2)/(-I a + γ)^2]))/(h^2 π u^3 v^2))

then

In[21]:= eqn = 
8 h^2 π u^3 v^2 == 
 FullSimplify[
  ExpandAll[(-16 (-I a + γ) (1 - Sqrt[
        1 + (h^2 u^2 v^2)/(-I a + γ)^2])) ( π u (-I a + \
 γ) Sqrt[1 + (h^2 u^2 v^2)/(-I a + γ)^2])]]

Out[21]= 8 h^2 π u^3 v^2 == 
16 π u (h^2 u^2 v^2 + (a + I γ)^2 (-1 + Sqrt[
     1 + (h^2 u^2 v^2)/(-I a + γ)^2]))

 In[22]:= Solve[eqn, u]
Out[22]= {{u -> 0}}

 In[23]:= Reduce[eqn, u]

 Out[23]= (a h v + I h v γ != 0 && u == 0) || (u != 0 && 
  a + I γ != 0 && v == 0) || (a + I γ != 0 && v == 0 &&
    u == 0) || (a v + I v γ != 0 && h == 0 && 
   u == 0) || (v != 0 && u != 0 && a + I γ != 0 && h == 0)