Defining a function via pattern matching with SeriesData

Question

I want to define a function myLO that gives me the leading order of a series expansion in Mathematica (the whole term, not just the coefficent).

My idea is, given that any series expansion in Mathematica has de form SeriesData[x, x0, {a0, a1, ...}, nmin, nmax, den] I can use this structure to construct my function. I did it the following way:

myLO[SeriesData[x_,x0_,coefs_List,nmin_Integer,nmax_Integer,den_Integer]]:=First@coefs Power[(x-x0),nmin/den]

And it works OK, e.g.

serie = Series[ Exp[x-1]/Sqrt[x-1],{x,1,3}]

myLO[serie]
(* 1/Sqrt[-1 + x] *)

But in the definition it gives me an error:

SeriesData::sdatc: "Coefficient specification coefs_List in SeriesData[x_,x0_,coefs_List,nmin_Integer,nmax_Integer,den_Integer] is not a list."

I don't understand this error, I am specifying that the header of lcoefsmust be List, but the function seems to do not notice it. I can write {a__} instead, and it won't trigger (but it will complain about the integers), but I want to handle the list as a whole.

How can I avoid this? Or how can I improve this definition?

Answer 1

Explanation

Using the construction arg_List indeed specifies that arg should be given as a list, and this is a correct construction to match an expression of the form arg = {subexpression} when the outer head enclosing arg_List does not evaluate.

For instance, the function f defined by

f[g[arg_List]] := Total[arg]

expects an argument with head List in order to trigger the right-hand side. The difference with your situation comes from the symbol g. In the above, there is no definition associated to it; in your example, g is SeriesData and there is a definition associated to it.

What happens is that the expression

SeriesData[x_, x0_, coefs_List, nmin_Integer, nmax_Integer, den_Integer]

evaluates (even though it is written in a SetDelayed construction --- see below). Since SeriesData is expecting a list as a third argument and integers afterwards, it will complain when given arguments with other heads:

Head /@ {coefs_List, nmin_Integer, nmax_Integer, den_Integer}
(* {Pattern, Pattern, Pattern, Pattern} *)

After throwing the error message, the same expression SeriesData[...] will be returned, the definition will be constructed with this expression, and the latter will be used subsequently for the pattern-matching, which explains why an output is still generated when calling the definition.

Solution

The solution to make this work is to wrap the expression in the symbol HoldPattern, in order to prevent the evaluation of the expression.

Defining

myLO[HoldPattern@ 
  SeriesData[x_, x0_, coefs_List, nmin_Integer, nmax_Integer, den_Integer]
] := First@coefs Power[(x - x0), nmin/den]

will not generate any error messages.

Additional comments

The fact that a symbol has the attribute HoldAll does not mean that it will not evaluate its arguments. It means instead that its definition is triggered before evaluating the arguments.

Evaluation of those arguments will then depend on the internal of the function. So, the arguments may not be evaluated at all, or they can be evaluated once, or several times. About SetDelayed, its first argument (left-hand side) does evaluate, as shown by the generated error message.